Well, one problem is that the first pass of your while loop for FILE2 will consume all the lines in that file and leave the file handle pointing to the end of the file (i.e eof == 1). So that on the next pass there's no more data to be read, and no lines will match.

A simple fix is to move the open FILE2 inside the loop so that you open it each time you need it.

    while (<FILE1) {
    ...
        open (FILE2,'<',"name");
        while(<FILE2>) {
        ...
        }
        close FILE2;
    }
[download]

It isn't very efficient to keep reopening the same file ,and there are lots of better ways but they are more complex, and we would need to know more about your problem. e.g. how big are your files?

This, Basic debugging checklist , has a number of ways you can try to understand why any code isn't doing what you expect.

Using autodie saves lots of typing for simple programs like this.

That's done the trick, thank you for your help! Autodie does make a lot more sense so i will use that in future.

Apologies, i didn't know that, i have edited both posts to include this.

You can read the positions into an array by themsevels, and then open the second file and iterate over the array to find lines where the positions are enclosed within the ranges. That way you open each file only once

use strict;
use warnings;

open(my $fh1, "<","positions.txt") or die("could not open file $!\n");
my @positions;    #hold the positions to be compared
while(my $line=<$fh1>){
    chomp $line;
    push @positions,$line;
    }

open(my $fh2, "<","coords_orientation.txt") or die("could not open fil
+e $!\n");
while(my $line=<$fh2>){
    chomp $line;
    my @record=split(" ",$line); #split the coords_orientation.txt on 
+white space 
    foreach my $pos (@positions){
        if($pos > $record[0] && $pos <$record[1]){
            print "$pos @record\n";        
            }
        }
    }
[download]

use Modern::Perl '2014';
use Number::Interval;
use List::Util qw/first/;

# FILE1 data emulation
my @FILE1 = qw/99269 550 100 126477 1700/;

my @interval_objects;
while (<DATA>) {
    chomp;
    my ($start, $end, undef) = split;
    push @interval_objects,
        Number::Interval->new(
            IncMax => 0,
            IncMin => 0,
            Min    => $start,
            Max    => $end,
        );
}

for my $datapoint (@FILE1) {
    my $found = first {$_->contains($datapoint)} @interval_objects;
    say "$datapoint is in $found" if $found;
}

# FILE2 data emulation
__DATA__
517 1878 forward
700 2500 forward
2156 3289 forward
99000 100000 forward
22000 23000 backward
[download]

99269 is in (99000,100000)
550 is in (517,1878)
1700 is in (517,1878)
[download]

It will also only find the first interval that matches. if you want to find all intervals that match, replace the for-loop by:

for my $datapoint (@FILE1) {
    my @found = grep {$_->contains($datapoint)} @interval_objects;
    say "$datapoint is in @found" if @found;
}
[download]