#!/usr/bin/perl
use warnings;
use strict;

use Template;

my @arr = (
           { name => 'Foo', value => 1 },
           # { name => 'Bar', value => 2 },
          );

'Template'->new
    ->process(\'TEST: [% FOREACH element IN arr.sort("name") %] [% ele
+ment.name %][% END %]',
              { arr => \@arr });
[download]

Output:

TEST: Foo
[download]

I've put together a test script demonstrating how my data model works. Please tell me this fails for you, or I might go insane. Bonus points if you can tell me how to fix it.

#!/usr/bin/perl

use strict;
use warnings;
use Template;

my $container = Container->new();
$container->add( 
  Object->new( name => 'foo', value => 10, usefulness => 0 )
);
$container->add(
  Object->new( name => 'bar', value => 20, meaning => 42 )
);

my $vars = {
  'container' => $container
};

my $template = <<EOT;
container=[% container %]
all:
[% FOREACH element IN container.all.sort('name') %]
[% element %] name is [% element.name %]
[% END %]
one:
[% FOREACH element IN container.one(10).sort('name') %]
[% element %] name is [% element.name %]
[% END %]
EOT

my $tt = Template->new();
$tt->process(\$template, $vars);

package Object;

sub new {
  my $class = shift;
  my $self = {@_};
  return bless($self, $class); 
}


package Container;

sub new {
  my $class = shift;
  my $self = {@_};
  return bless($self, $class); 
}

sub add {
  my $self = shift;
  my $new = shift;
  push @{$self->{'objects'}}, $new;
}

sub all {
  my $self = shift;
  return @{$self->{'objects'}};
}

sub one {
  my $self = shift;
  my $filter = shift;
  return grep { $_->{'value'} == $filter } @{$self->{'objects'}}; 
}
[download]

-- FloydATC

Time flies when you don't know what you're doing

Container's one method is returning a single Object object instead of an array reference with a single Object object inside.

The fix is quite simple:

sub one {
  my $self = shift;
  my $filter = shift;
  return [ grep { $_->{'value'} == $filter } @{$self->{'objects'}} ];
}
[download]

Output:

container=Container=HASH(0x1cc2e10)
all:

Object=HASH(0x1cdf6b0) name is foo

Object=HASH(0x1cdf788) name is bar

one:

Object=HASH(0x1cdf6b0) name is foo

Have one/all return arrayrefs, not lists?

sub all {
  my $self = shift;
  return $self->{'objects'};
}

sub one {
  my $self = shift;
  my $filter = shift;
  return [ grep { $_->{'value'} == $filter } @{$self->{'objects'}} ];
}
[download]

More a TT question, but what happens if you always append an empty hash to the array?

Of course doing the sort logic in Perl should always fix this.

More a TT question, but what happens if you always append an empty hash to the array?

This would solve the Template problem but it would also require that I check for empty hashes in every single place that array is used. I want to keep the workaround within the template if at all possible.

I'll see if I can find a way to do that.

-- FloydATC

Time flies when you don't know what you're doing

$ cat sort-list.tt2
[% MACRO blocker BLOCK %]
[% FOREACH element IN array.sort('name') %]
[% element.name %]
[%- END -%]
[%- END -%]

[%-
SET array = [
  { name => 'foo', value => 1 },
  { name => 'bar', value => 2 },
  { name => 'baz', value => 3 }
];
blocker
%]

[%-
SET array = [
  { name => 'bar', value => 2 },
];
blocker
%]

$ tpage sort-list.tt2


bar
baz
foo


bar
[download]

My code says it works ... so what does your code say?

I get the same result if I define the array within the template. If the array is served as a reference through Template::process() then it doesn't work as expected.

-- FloydATC

Time flies when you don't know what you're doing

I get the same result if I define the array within the template. If the array is served as a reference through Template::process() then it doesn't work as expected.

Thats just more words :) but I'm glad to see choroba got you to play ;) and you figured it out

You must be giving it a hash instead of an array ... don't know how you managed to write that :)

[% MACRO blocker BLOCK %]
[%     FOREACH element IN array.sort('name') %]
[%         element.name %]
[%-    END -%]
[%- END -%]
[%-
SET array = [
      { name => 'foo', value => 1 },
      { name => 'bar', value => 2 },
      { name => 'baz', value => 3 }
    ];
    blocker;
%]
[%-
    SET array = [ { name => 'bar', value => 2 }, ];
    blocker;
%]
[%-
## A HASH IS NOT AN ARRAY OF HASHES
    SET array = { name => 'bar', value => 2 };
    blocker;
%]
[download]

yadayadayada

* bar
* baz
* foo

* bar

*
*
[download]