janssene:

Yes, that's possible. it should be something like:

use strict;
use warnings;
use Data::Dump qw(pp);

my @a = qw(now is the time for all good men);
my %h;
add_val(\%h, 'FOO', @a);

print pp(\%h);

sub add_val {
    my ($hashref, $val, @keylist) = @_;
    die "Expected a list of keys!" unless @keylist;
    die "Expected a hashref!" unless "HASH" eq ref $hashref;

    while (@keylist > 1) {
        my $key = shift @keylist;
        $hashref->{$key} = {} if ! exists $hashref->{$key};
        $hashref = $hashref->{$key};
    }
    $hashref->{shift @keylist} = $val;
}
[download]

Untested, your mileage may vary, you can keep all the pieces it might break into, join(", ",@other_disclaimers).

Update: Fixed & tested this time.

...roboticus

When your only tool is a hammer, all problems look like your thumb.

roboticus++: Interesting, so at each iteration of the while loop it autovivifies the next key and you end up with a reference to the final memory location.

  # As long as we have multiple keys, access the next subhash
   while (@keys > 1) {
      my $key = shift @keylist;
      $hashref = $hashref->{$key};
   }
[download]

Should that be @keylist instead of @keys?

while (@keylist > 1) {
    my $key = shift @keylist;
    $hashref = $hashref->{$key};
}
[download]

Update: I just tried this and it doesn't work. $hashref = $hashref->{$key}; doesn't set anything in the hash and doesn't autovivify. I end up with an empty hash.

use strict;
use warnings;
use Data::Dump;
my %testhash;
my $hr = \%testhash;

my $count = 0;
while(<DATA>) {
    print "[", join('-',split ' ', $_), "]\n";
    add_val( $hr, ++$count, split ' ', $_);
}

dd \%testhash;

sub add_val {
    my ($hashref, $val, @keylist) = @_;
    die "Expected a list of keys!" unless @keylist;
    die "Expected a hashref!" unless "HASH" eq ref $hashref;

    # As long as we have multiple keys, access the next subhash
    while (@keylist > 1) {
      my $key = shift @keylist;
      $hashref = $hashref->{$key};
    }
    # Now set the value
    $hashref->{shift @keylist} = $val;
}

__DATA__
a1 a2 a3
jjj kkk lll mmm


Output:
[a1-a2-a3]
[jjj-kkk-lll-mmm]
{}
[download]

Update again: With the addition of the subhash from your update it works. Thanks.

Output:
[a1-a2-a3]
[jjj-kkk-lll-mmm]
{
  a1  => { a2 => { a3 => 1 } },
  jjj => { kkk => { lll => { mmm => 2 } } },
}
[download]

Lotus1:

Yes, it should be @keylist. I also needed to create the subhash when it didn't exist. I've made the appropriate corrections to the parent node.

...roboticus

When your only tool is a hammer, all problems look like your thumb.

$cf{$k1}{$k2}{$k3}{"hlst"} //= "";
[download]

> $cf{$k1}{$k2}{$k3}{"hlst"} //= "";

IMHO the best solution in this case where autovivification is wanted.

For completeness if the perl version is to old for defined-or, one could use a ref to the hash value.

$ perl
use Data::Dumper;

my $hash;

my $rval = \ $hash{a}{b}{c}{"hlst"};

$$rval = "" unless defined $$rval;

print Dumper \%hash;

__END__
$VAR1 = {
          'a' => {
                   'b' => {
                            'c' => {
                                     'hlst' => ''
                                   }
                          }
                 }
        };
[download]

or you can define an defined-or-assign function to do so

use Data::Dumper;

my $hash;

defor( $hash{a}{b}{c}{"hlst"} , "");

print Dumper \%hash;

sub defor {
    $_[0] = $_[1] unless defined $_[0];
}

__END__
$VAR1 = {
          'a' => {
                   'b' => {
                            'c' => {
                                     'hlst' => ''
                                   }
                          }
                 }
        };
[download]

Cheers Rolf

_{(addicted to the Perl Programming Language and ☆☆☆☆ :)}

  DB<1>  @keylist = qw/one two three four/;

  DB<2>  $hash = ();

  DB<3>  sub make_hash {$string = join '}{', @_ ; $string =  '$hash{' 
+. $string . '} = 0'; eval $string;}

  DB<4> make_hash(@keylist);

  DB<5> x \%hash;
0  HASH(0x6004f9dc0)
   'one' => HASH(0x6004f9d48)
      'two' => HASH(0x6004f9c10)
         'three' => HASH(0x6004f9be0)
            'four' => 0

  DB<6> make_hash( qw/jan feb mar apr may jun/)

  DB<7> x \%hash;
0  HASH(0x6004f9dc0)
   'jan' => HASH(0x60064b430)
      'feb' => HASH(0x60064b508)
         'mar' => HASH(0x60064b538)
            'apr' => HASH(0x600500860)
               'may' => HASH(0x60064eab0)
                  'jun' => 0
   'one' => HASH(0x6004f9f58)
      'two' => HASH(0x600639458)
         'three' => HASH(0x6006175e8)
            'four' => 0
[download]

Data::Diver.

Hi Roboticus, just wondering, my problem is that I can have situations where some keys can be not defined yet. so when filling in my value..$cf{$k1}{$k2}{$k3} = "$val", that $k2 and $k3 are not defined yet in the hash, for the given $k1. is there some specific command to create the ref for $cf{$k1}{$k2} before going further on $k3 ?

Perl does this automatically, it's called autovivification.

You only have an issue if you want to avoid it.

update

hmm thats the problem if you post from a mobile client without possibility to test...

I'll update a working solution, though using Data::Diver should help already.

update

use warnings;
use strict;
use Data::Dumper;

my @keys="a".."d";
my %hash=();
my $href=\%hash;

my $lastkey= pop @keys;

for my $key (@keys) {
  $href =
    $href->{$key} //= {} ;
}

$href->{$lastkey} = "";

print Dumper \%hash;
[download]

--->

$ perl dive.pl 
$VAR1 = {
          'a' => {
                   'b' => {
                            'c' => {
                                     'd' => ''
                                   }
                          }
                 }
        };
[download]

update

fixed bug

Cheers Rolf

_{(addicted to the Perl Programming Language and ☆☆☆☆ :)}

janssene:

Yes, I've botched that in my original answer. I've fixed it, though. (I also notice that LanX's repair is cleaner than mine. I need to start using the //= operator more often.

...roboticus

When your only tool is a hammer, all problems look like your thumb.