See Term::Visual

Hello GotToBTru,

Nice screen name and verse below...anyways I installed POE and Term::Visual via cpan and when I try to run the examples I get the following error which can be view at: www.cfnet.org/~files/TERM-VISUAL-ERROR-1.JPG any solutions? Thanks.

You may have to upgrade your Perl distribution. See this thread: perl reports fastcwd 'redefined' when using Cwd and -W, especially ikegami's remarks on how Cwd works.

- Luke

Sorry, no actual experience with the package, just what Google turned up.

1 Peter 4:10

Hello Luke,

I'm not against using Perl Modules which I have been using alot of Perl Modules. Will Term::Cap work under Win32? I am using Activestate Perl and Win32::Console module. Thanks.

Cpan Testers says that version 1.16 of the module works with perl 5.20.0 on Win32. Older versions are listed there, too. They don't mention ActiveState explicitly, however.

Don't know how to easily find this page via CPAN, but on the Module's MetaCPAN page, there is a link "Testers" top left.

Hello Luke,

Would it be to much to ask for a simple working example? Thanks

Not at all. Here's something simple that I had in mind when I suggested Term::Cap. Don't worry about the use v5.14, it's only needed for 'say', and it replaces use strict;. Just use something recent you have available. Unfortunately, I'm not able to test this under Windows, which I suppose is the OS you're working on, but still, it may be of some use. Best luck with your project.

 
#!/usr/bin/perl
use POSIX;
use Term::Cap;
use v5.14;

# init the term
my $termios = new POSIX::Termios;
$termios->getattr;
my $ospeed = $termios->getospeed;
my $tc = Tgetent Term::Cap { TERM => undef, OSPEED => $ospeed };

# require the following capabilities
$tc->Trequire(qw/cl cd ce cm co li/);

# clear screen, clear to end of line, clear to end of screen
sub cl_scr  { $tc->Tputs('cl', 1, *STDOUT) } 
sub cl_line { $tc->Tputs('ce', 1, *STDOUT) } 
sub cl_end  { $tc->Tputs('cd', 1, *STDOUT) }

# move the cursor
sub gotoxy {
    my($x, $y) = @_;
    $tc->Tgoto('cm', $x, $y, *STDOUT);
}

sub pline {
    my ($line_no, $string) = @_;
    gotoxy(0,$line_no);
    cl_line;
    print $string;
}

my @log = map { " > " } (0..9);

# redraw the log
sub flush_log {
    my $i = 0;
    for my $logline (@log) {
        pline ($i, $logline);
        $i++;
    }
    pline ($i, "==================================================");
    gotoxy(0,++$i);
    cl_end;
}

# print line to log
sub plog {
    my $line = shift;
    shift @log;
    push @log, " > $line";
    flush_log;
}

my $correct = 42;
my $number;
my $choice;

flush_log;

do {
    print "What is the correct number: ";
    chomp($number = <STDIN>);

    if ($number == $correct) {
        plog "Game result: WIN";
        say "Good answer. Play again? (y/n)";
        chomp($choice = <STDIN>);
    }
    else {
        plog "Game result: LOSE";
        say "Bad answer. Play again? (y/n)";
        chomp($choice = <STDIN>);
    }
} while ($choice eq 'y');
[download]

Relevant info from termcap manual:

`cl'
    String of commands to clear the entire screen and position the cur
+sor 
    at the upper left corner. 
`cd'
    String of commands to clear the line the cursor is on, 
    and all the lines below it, down to the bottom of the screen. 
    This command string should be used only with the cursor in column 
+zero.
`ce'
    String of commands to clear from the cursor to the end of the curr
+ent line. 
`cm'
    String of commands to position the cursor at line l, column c. 
    Both parameters are origin-zero, and are defined relative to the s
+creen, 
    not relative to display memory.
`co'
    Numeric value, the width of the screen in character positions.
`li'
    Numeric value, the height of the screen in lines.
[download]

What it should look like:

 > 
 > 
 > 
 > 
 > 
 > 
 > Game result: LOSE
 > Game result: WIN
 > Game result: LOSE
 > Game result: LOSE
==================================================
Bad answer. Play again? (y/n)
y
What is the correct number:
[download]

- Luke

Hello Luke,

No this will not work under WinXP...I did give a vote for providing the example.