I do a lot of work in Putty and need to look at icon files sometimes. I thought it would be cool to get Putty to display them in bash directly, rather than using X11 forwarding. This is not meant to be any kind of substitute for real graphics, but is a quick way to see whether a particular image file (like an icon or a web button) is what I think it is. Note that it requires 256 color to be turned on in Putty, that your Terminal setting is putty-256color, and it only handles image formats handled by GD (png, jpg, gif).

#!/usr/bin/perl
# Steve Flitman - released to Public Domain - display a small image on
+ the console using 256-color mode Putty/Screen
# Color output to terminal derived from Todd Larason <jtl@molehill.org
+>

use strict;
use warnings;
use GD;

unless (@ARGV) {
   die "img file ...\nDisplay files at command line using ANSI 256 col
+or mode\n";
}

# set colors 16-231 to a 6x6x6 color cube
for (my $red=0; $red<6; $red++) {
    for (my $green=0; $green<6; $green++) {
        for (my $blue=0; $blue<6; $blue++) {
            printf("\x1b]4;%d;rgb:%2.2x/%2.2x/%2.2x\x1b\\",
                   16 + ($red * 36) + ($green * 6) + $blue,
                   ($red ? ($red * 40 + 55) : 0),
                   ($green ? ($green * 40 + 55) : 0),
                   ($blue ? ($blue * 40 + 55) : 0));
        }
    }
}

# colors 232-255 are a grayscale ramp, intentionally leaving out black
+ and white
for (my $gray=0; $gray<24; $gray++) {
    my $level=($gray * 10) + 8;
    printf("\x1b]4;%d;rgb:%2.2x/%2.2x/%2.2x\x1b\\",
           232 + $gray, $level, $level, $level);
}

my ($file,$x,$y,$r,$g,$b,$color,$index,$image,$width,$height);
for $file (@ARGV) {
   die "Cannot read $file: $!\n" unless -r $file;
   my $image=GD::Image->new($file);
   die "Not a recognized image format: $file\n" unless defined $image;
   my ($width,$height)=$image->getBounds();
   for (my $y=0; $y<$height; $y++) {
      for (my $x=0; $x<$width; $x++) {
         my $index=$image->getPixel($x,$y);
         my ($r,$g,$b)=$image->rgb($index);
         if ($r+$g+$b==0) {   # black
            $color=0;
         }
         elsif ($r==255 && $g==255 && $b==255) {   # white
            $color=15;
         }
         elsif ($r==$g && $g==$b) {  # grayscale
            $color=232+($r>>3);
         } else {
            $color=16+(int($r/42.6)*36)+(int($g/42.6)*6)+int($b/42.6);
+    # smush 256 color range to 6 levels
         }
         print "\x1b[48;5;${color}m ";
      }
      print "\x1b[0m\n";  # reset
   }
   print "\x1b[0m\n";  # reset
}
exit;
[download]

Dedicated to the memory of John Todd Larason, http://molehill.org

Enjoy!

SSF