The following isn't JSON:

{"abc":"abc\'abc"}
[download]

What are you trying to do? You might be trying to generate a JavaScript string literal from JSON, but then you'd want something like the following.

'{"abc":"abc\'abc"}'
[download]

If that's what you want, you can use the following:

{
    my %translations = (
        "\r" => "\\r",
        "\n" => "\\n",
        "'"  => "\\'",
        "\\" => "\\\\",
    );
    
    my $meta_chars_class = join '', map quotemeta, keys %translations;
    my $meta_chars_re = qr/([$meta_chars_class])/;
    
    sub text_to_jslit {
        my $text = shift;
        $text =~ s/$meta_chars_re/$translations{$1}/g;
        return "'$text'";
    }
}
[download]

As a Template-Toolkit plugin:

package Template::Plugin::JavaScriptLiteral;

use strict;
use warnings;

use Template::Plugin::Filter qw( );

our @ISA = 'Template::Plugin::Filter';

my %translations = (
    "\r" => "\\r",
    "\n" => "\\n",
    "'"  => "\\'",
    "\\" => "\\\\",
);
    
my $meta_chars_class = join '', map quotemeta, keys %translations;
my $meta_chars_re = qr/([$meta_chars_class])/;
    
sub init {
    my $self = shift;
    $self->install_filter('jslit');
    return $self;
}

sub filter {
    my ($self, $text) = @_;
    $text =~ s/$meta_chars_re/$translations{$1}/g;
    return "'$text'";
}

1;
[download]

For example,

// PARAMS: { data => { abc => "abc'abc" } }

[% USE JSON %]
[% USE JavaScriptLiteral %]
var json = [% data | json | jslit %];
alert(json);  // {"abc":"abc'abc"}
[download]

However, one usually wants to assign the JSON to a JS var, not a string representation of it.

// PARAMS: { data => { abc => "abc'abc" } }

[% USE JSON %]
var data = [% data | json %];
alert(data.abc);  // abc'abc
[download]

Thanks! I guess my statement was a bit wooly. I'm really trying to do create a javascript literal that I can include like this:

var data = JSON.parse('{"abc":"abc\'abc"}');
[download]

.. and must therefore escape the string. I've written code that's essentially like in proposal one. Thanks!

If you know the JSON is valid, var data = {"abc":"abc'abc"}; is equivalent.

I have not used it myself (no need) but from the documentation, it sounds as though JavaScript::Value::Escape may be what you are looking for. If not, please say why not because it sounds like escaping literals for embedding into Javascript is its raison d'être.

googling CPAN JSON spits out

• JSON
  http://search.cpan.org/perldoc?JSON
  JSON::PP was earlier included in the JSON distribution, but has since Perl 5.14 been a core module. For this reason, JSON::PP was removed from the JSON ...
• JSON::XS
  http://search.cpan.org/perldoc?JSON::XS
  This module converts Perl data structures to JSON and vice versa. Its primary goal is to be correct and its secondary goal is to be fast. To reach the latter goal it ...
• JSON::PP
  http://search.cpan.org/perldoc?JSON%3A%3APP
  JSON::XS is the fastest and most proper JSON module on CPAN. It is written by Marc Lehmann in C, so must be compiled and installed in the used environment.

Well, Jeppe already knew about JSON since he's using it already. And there are other modules that do the same thing (JSON::DWIM will work the same on blessed or not blessed objects for exemple). But as far as I understand the issue here is to escape some chars (the single quote at least apparently) in strings. And unlike Data::Dump, JSON doesn't seem to provide a call back to allow custom output for any data type (objects can have a method to convert themselves to JSON, but here the strings are not blessed).

Jeppe, wouldn't s/'/\\'/g; on the output JSON be enough?

OK, right, sorry.

My fault was that I read it as JSON has a bug in escaping quotes!

( JS - contrary to Perl - doesn't give single and double quotes different meanings, but that doesn't mean they need to be escaped, so no bug! )

so whats happening here is that Jeppe wants the data altered, and IMHO this should already be done on Perl's side before escaping.

Your suggestion of a general s/'/\\'/g would only work if the JSON output doesn't use single quotes as delimiter.¹

Cheers Rolf

_{(addicted to the Perl Programming Language and ☆☆☆☆ :)}

update

¹) ah sorry, I didn't know that single quotations are invalid in JSON

from JSON::PP

   allow_singlequote
           $json = $json->allow_singlequote([$enable])

       If $enable is true (or missing), then "decode" will accept JSON
+ strings
       quoted by single quotations that are invalid JSON format.
[download]

Not sure why you would think that a JSON module should provide a hook for providing data that is not, well, just a different form of valid JSON.

Update: note really invalid, just not the simplest form.

> ... for providing data that is not, well, JSON.

Shouldn't "\'" and "'" be synonymous in the end?

Quoting of non-meta characters does no harm, at least in Perl.

So I don't understand why it's not JSON, it might be redundant but it's still valid.

Cheers Rolf

_{(addicted to the Perl Programming Language and ☆☆☆☆ :)}

Point taken, tested, and my response updated.

It still seems, imo, that this is something outside of the scope of what the JSON module should be providing. I suppose, if one really wanted to, one could just escape every non-escaped character and be done with it.

--MidLifeXis