rebkirl:

You can get both the index and the value from an array by iterating through it like this:

$ cat x.pl
use strict;
use warnings;

my @foo = qw( apple pear banana );

while (my ($x,$y) = each @foo) {
    print "<$x, $y>\n";
}

$ perl x.pl
<0, apple>
<1, pear>
<2, banana>
[download]

...roboticus

When your only tool is a hammer, all problems look like your thumb.

That's one of the cases where it's easier (and actually required) to iterate over the indexes rather the elements themself. $#data is the index of the last element in the array @data:

my @ref = qw(Red Green Yellow);
my @data = qw(Yellow Black Yellow Red White Yellow);
for my $search (@ref)
{
  my @found;
  for my $index (0..$#data)
  {
    if ($data[$index] eq $search)
    {
      push @found, $index;
    }
  }
  print "$search: [@found]\n";
}
[download]

Red: [3]
Green: []
Yellow: [0 2 5]
[download]

Also, while it's kind of acceptable to not use strict when testing, you should always avoid using one letter names for variables. Mostly for clarity, but also because some of them might have some hidden side effect / behaviour.

Thanks Eily. I am not familiar with the 'grep' feature, only loops and arrays structures. Is it possible to print strings for each output line "print "$search: @found\n";" ?. Thank you a lot!

I'm sorry I did not get that question. I know that my code output is not exactly what you asked for, but the main logic is there. If you've already tried to adapt it to your needs, please show us your updated code, and what's missing for you to continue.

Loop over the indexes in the inner loop instead of the values and push matches to a list.

#!/usr/bin/env perl 
use strict;
use warnings;
use feature 'say';

my @A = ("Red", "Green", "Yellow");
my @B = ("Yellow", "Black","Yellow","Red", "White", "Yellow");

for my $x (@A){
    my @matches;
    for my $y (0 .. $#B){
        push @matches, $y if $B[$y] eq $x;
    }
    say $#matches < 0 ? "$x is missing" : "$x at index " . join ', ', 
+@matches;
}
[download]

I am new in Perl

When you fancy something more advanced you can push into a hash of arrays (HoA) instead. That way you can store the results rather than just printing them out as you go. HTH.

Thank you a lot. I learned vey basic codes and not yet seen feature 'say' and 'HoA' but it could be useful for next steps!

The easiest way is to increment a variable $index++ inside your @B loop.

Please note that swapping the loops would make sense here.

The most efficient way though would be using a hash %A to lookup set elements in @A thus avoiding that loop.

It's considered polite to inform about crossposting to prevent people not attending both sites from unnecessary work (i.e. solving a problem already solved at the other side of the internets).