Zaxonxp has asked for the wisdom of the Perl Monks concerning the following question:

Hi all,

I wrote the script to show the MP3 tags in the table (parsing output of the eyeD3 command), so I check the length of each string and store the longest it in the hash. Later on I am using this info to print it like this:

 printf("%*s", $len, $str)

The problem is that each time I run the script I am getting a different results (different strings lengths for the same input). Is this a bug in a Perl? If not, then how to make it work the same way all the time? My Perl version is v5.24.1 

#!/usr/bin/perl
use warnings;
use strict;
use Data::Dumper;

$| = 1;

sub update_max(\%$$);

my $inp = $ARGV[0] || '*.mp3';

my @list = qx/eyeD3 --no-color $inp/;
chomp(@list);

my %data; 
my $nr = 0;
my @attr = qw(artist album track tracks year genre title size file );

foreach my $line (@list) {

    next if ($line =~ m/^-+$/);

    if ($line =~ m#([^/]*\.mp3).*\[ (\d*\.\d*) MB \]#) {
        $nr++;
        $data{$nr}{'file'} = $1;
        $data{$nr}{'size'} = $2;
    }

    if ($line =~ m#title: (.*)#)     { $data{$nr}{'title'}  = $1; }
    if ($line =~ m#^artist: (.*)#)   { $data{$nr}{'artist'} = $1; }
    if ($line =~ m#album: (.*)#)     { $data{$nr}{'album'}  = $1; }

    if ($line =~ m#(release|recording) date: (.*)#){ 
        $data{$nr}{'year'}   = $2; 
    }
    
    if ($line =~ m#track: (\d+)/(\d+).*genre:\s+(\w+)#)  { 
        $data{$nr}{'track'} = $1; 
        $data{$nr}{'tracks'} = $2; 
        $data{$nr}{'genre'} = $3;
    }
}

# count length of the strings
my %len;
foreach $nr (keys %data) {
    foreach my $att (@attr) {
        $len{$att} = 0;
        update_max(%len, $att, $data{$nr}{$att});
    }
}

# print using lengths
foreach $nr (sort keys %data) {
    printf("|");

    foreach my $att (@attr) { 

        if ($att eq 'track') {
            printf(" %02d |", $data{$nr}{$att});
        } else {
            printf(" %-*s |", $len{$att}, $data{$nr}{$att});
        }
    }
    printf("\n");
}

######################################################
sub update_max(\%$$) {
    my ($ref_data, $att, $val) = @_;

    my $siz  = $ref_data->{$att};
    my $siz2 = length($val);

    if ($siz < $siz2) {
        $ref_data->{$att} = $siz2;
    }
}

[download]

Replies are listed 'Best First'.
Re: Printf with a minimum width.
by Zaxonxp (Novice) on May 28, 2019 at 12:04 UTC
    I found a guilty line. :) 
    # count length of the strings
my %len;
foreach $nr (keys %data) {
    foreach my $att (@attr) {
        $len{$att} = 0;         # <====== here
        update_max(%len, $att, $data{$nr}{$att});
    }
}

    [download]
    I was getting warnings, so I tough that I will initialize the hash value here. But this made the reset of the $len{$att} each time the new key from %data was analyzed. So I removed the line and put this instead: 
    sub update_max(\%$$) {
    my ($ref_data, $att, $val) = @_;

    if (! $ref_data->{$att} ) {
        $ref_data->{$att} = 0;
    }

    my $siz  = $ref_data->{$att};
    my $siz2 = length($val);

    if ($siz < $siz2) {
        $ref_data->{$att} = $siz2;
    }
}

    [download]
[reply]
[d/l]
[select]
Re: Printf with a minimum width.
by Zaxonxp (Novice) on May 28, 2019 at 13:02 UTC
    Here is the version which uses Text::ANSITable; 

    #!/usr/bin/perl
use warnings;
use strict;
use Text::ANSITable;

my $inp = $ARGV[0] || '*.mp3';

my @list = qx/eyeD3 --no-color $inp/;
chomp(@list);

my %data; 
my $nr = 0;
my @headers  = qw(artist album track tracks year genre title size file
+ );

foreach my $line (@list) {

    next if ($line =~ m/^-+$/);

    if ($line =~ m#([^/]*\.mp3).*\[ (\d*\.\d*) MB \]#) {
        $nr++;
        $data{$nr}{'file'} = $1;
        $data{$nr}{'size'} = $2;
    }

    if ($line =~ m#title: (.*)#)     { $data{$nr}{'title'}  = $1; }
    if ($line =~ m#^artist: (.*)#)   { $data{$nr}{'artist'} = $1; }
    if ($line =~ m#album: (.*)#)     { $data{$nr}{'album'}  = $1; }

    if ($line =~ m#(release|recording) date: (.*)#){ 
        $data{$nr}{'year'}   = $2; 
    }
    
    if ($line =~ m#track: (\d+)/(\d+).*genre:\s+(\w+)#)  { 
        $data{$nr}{'track'} = $1; 
        $data{$nr}{'tracks'} = sprintf("%02d", $2); 
        $data{$nr}{'genre'} = $3;
    }
}

my $t = Text::ANSITable->new( 'use_box_chars' => 1, 'use_utf8' => 1, c
+ell_pad => 0);

$t->border_style('Default::bold');
$t->columns(\@headers);

foreach my $key (sort { $a <=> $b } keys(%data)) {

    my @row;
    foreach my $att (@headers) {
        push(@row, $data{$key}{$att});
    }

    $t->add_row(\@row);
}

binmode(STDOUT, ":utf8");
print $t->draw;

    [download]

[reply]
[d/l]
[select]

Back to Seekers of Perl Wisdom