It is probably due to the split not cleaning up leading spaces, or possible sequential spaces. It is hard to say without seeing that part of the code and the data.

Could you provide the code and some example data? Your other response indicates it is not the same as your previous post.

In any case, it could be cleaned up using a map or another loop, possibly embedded in your other code (but that could become a bit too obfuscatory).

@arr = map {s/^\s+//} @arr;
[download]

I am not sure how to delete/correct my reply looking at the documentation. Would you mind to point me to the right document? Thanks!

See How do I change/delete my post? paying particular attention to the section Why shouldn't I delete a node or its content?

Here is the code. The data has an extra blank in. The comment line does not work on the @multi_array, I suspect. I cannot figure out, too, how to print the added index as integers i.e. how to apply map to a part of the array.

#!/usr/bin/perl -w

# read data
my @multi_array; push @multi_array, [split(',', $_)] for <DATA>;
#@multi_array = map {s/\s//} @multi_array;

# add counter column
my $i = 0; (chomp $_->[1],$_->[2] = sprintf ("%d",$i++)) for @multi_ar
+ray;
#or
push @{ $multi_array[$_] }, $_ for 0 .. $#multi_array;

# modify columns
($_->[0] *= 1.0, $_->[1] /= 1.0) for @multi_array;

# screen output    
print join(",", map { sprintf "%e", $_ } @{$_}),"\n" for @multi_array;

__DATA__
0.00000000e+00, 2.41644835e+00
1.20048018e-04, 2.38938189e+00
2.40096037e-04, 2.36473989e+00
[download]

You could build the array while reading the data

#!/usr/bin/perl
use strict;
use warnings;

my @AoA = (); # ArrayOfArrays
while (<DATA>){
  s/\s//g;
  my @tmp = split ',',$_;
  $tmp[0] *= 1.0;
  $tmp[1] /= 1.0;
  $tmp[2]  = $.;
  push @AoA,\@tmp;
}

printf "%e,%e,%d\n",@$_ for @AoA;

__DATA__
0.00000000e+00, 2.41644835e+00
1.20048018e-04, 2.38938189e+00
2.40096037e-04, 2.36473989e+00
[download]

poj

The solution by poj in 11100896 is cleaner as it handles the extra space at read time. However, you might only want to remove those following a comma, for which you can pass a regex to split.

push @multi_array, [split(/,\s*/, $_)] for <DATA>;
[download]

I also gave an incorrect example for the map in my previous post, as the code did not operate on array refs. The map can be replaced by code like this:

foreach my $row (@multi_array) {
    s/^\s+// foreach (@$row);
}
[download]

And it's a stylistic thing, but I would avoid using so many postfix loops, and only use the topic variable where it is clearer to do so (you might have good reasons to think differently, though). For example, this code snippet is getting difficult to read at the first pass (for me at least):

# modify columns
($_->[0] *= 1.0, $_->[1] /= 1.0) for @multi_array;
[download]

It is clearer as this (similar to what poj posted):

for my $row (@multi_array) {
    $row->[0] *= 1.0;
    $row->[1] /= 1.0;
}
[download]

And the nested foreach loops above could be:

foreach my $row (@multi_array) {
    foreach my $item (@$row) {
        $item =~ s/^\s+//;
    }
}
[download]