Do you mean this?

#!/usr/bin/env perl 
use strict;
use warnings;

my @owner_grouprights = ('11', '14');

my @matches = grep { /4|5|6|7|8|9|10|11|12/ } @owner_grouprights;

if (@matches) {
    print "test2";
}
[download]

Use "smartmatch" at your peril.

Hello Hippo

that's a good idea. Thank you.

regards

Set::Scalar->new(qw(11 14))->intersection(
    Set::Scalar->new(qw(4 5 6 7 8 9 10 11 12))
)->members
# 11
[download]

Hello Daxim

thanks so far.

Can't locate object method "new" via package "Set::Scalar" (perhaps you forgot to load "Set::Scalar"?)

I have a restricted Perl environment here and can not install packages.

but thanks and regards

can not install packages

Just fatpack the module.

Smartmatch ~~ and given/when are definitely experimental features in that it is still possible they will undergo radical changes, there is discussion on P5P about this from time to time. In other words, by using them, it's very possible your code will not be future proof. I would strongly recommend staying away from them. Luckily, there are lots of alternatives, see the replies in these threads:

• Testing multiple variables against the same criteria (IF statement)
• Check multiple array elements for a single condition

#!/usr/bin/env perl    

use strict;
use warnings;
use 5.010;

# Don't really need the qw, since these are numbers, but the original
# code explicitly made them strings, so whatever.
my @owner_grouprights = qw( 11 14 );

my %rights_hash;
$rights_hash{$_}++ for @owner_grouprights;

if (exists $rights_hash{11}) {
  say "test3";
}

for (4 .. 12) {
  if (exists $rights_hash{$_}) {
    say "test2";
    last; # avoid duplicate messages if more than one is present
  }
}

# Or, alternately:

if (grep /4|5|6|7|8|9|10|11|12/, keys %rights_hash) {
  say "test2 alt";
}

# Note, though, that the two alternatives are not equivalent.  The
# first (if exists) only returns exact matches, while the second
# (grep) also finds substring matches. So, e.g., 114 would match the
# 'grep' version, but not the 'if exists' version. Adding begin/
# end-of-string anchors (^/$ or \A/\Z) to the 'grep' version's regex
# will disallow partial matches if you want that, but don't want the
# explicit 'for' loop.

my $owner_grouprights = join( ' ', sort keys %rights_hash);

my @testarr = (4 .. 12);
for my $tst (@testarr) {
  if (exists $rights_hash{$tst}) {
    say "$tst hit!";
  } else {
    say "$tst miss";
  }
}
[download]

Hello @dsheroh,

thank you very much. It seems the hash solution is the most best one can use in my case.

Thanks and have a nice day.

#!/usr/bin/perl


use strict;
use warnings;

my $VAR1 = [
          '11',
          '14'
        ];
        
#create a hash...
my %owner_grouprights = map{$_=>1}@$VAR1;

if ($owner_grouprights{'11'})
{
   print "test3-> 11 exists as a groupright\n";
}


# you say: "the big deal -- if it only would work" WHAT??
### what do you expect???

if (grep{/4|5|6|7|8|9|10|11|12/} keys (%owner_grouprights))
{
   print "test2->some number exists as a groupright\n";  #11 exists
}


# with loop
my $testarrorig = '4|5|6|7|8|9|10|11|12';
my @testarr = split( /\|/, $testarrorig );

foreach my $tst ( @testarr ) 
{
  if (exists $owner_grouprights{$tst})
  {
     print "$tst hit!\n";
  }
}
__END__
test3-> 11 exists as a groupright
test2->some number exists as a groupright
11 hit!
[download]

Hello marshall,

thanks for the hints, there are some real good points.

One is you did the same thing with the match, same as Hippo above. Thanks

A very good hint is the one with the hash. Thanks.

The last one again is a loop. Some say this is not elegant ... But it works so far.

Thanks for all, regards.