in reply to Re^2: How to Map a scalar to a key that is an array?
in thread How to Map a scalar to a key that is an array?

I did. Its an interesting read. As a FYI for anyone else having this question, my final program looked Thus: 
#!/usr/bin/perl
#use strict;
#use warnings;
#use Data::Dumper;

my %data;

{
    local $/ = '';
    while (<>) {
        chomp;
        my ($key, $data) = split /\n/;
        $data{$key} = $data;
    }
}
#print %data;
my $key;
# my $data;
 foreach $key (keys %data) {
#     print "$key\n";
     print "$key,$data{$key}\n";
 }

[download]
"Two Wheels good, Four wheels bad."

Replies are listed 'Best First'.
Re^4:How to Map a scalar to a key that is an array?
by jdporter (Paladin) on Aug 01, 2019 at 21:56 UTC 
    my %data = do { local $/ = ''; map { chomp; split /\n/, $_, 2 } <> };

    [download]
    my %data = map /^(.*?)\n(.*)\n/s, do { local $/ = ''; <> };

    [download]
[reply]
[d/l]
[select]
Re^4: How to Map a scalar to a key that is an array?
by Laurent_R (Canon) on Aug 01, 2019 at 21:15 UTC 
    #use strict;
#use warnings;

    [download]
    Why do you comment out these two lines? It is usually a very bad idea.

    Otherwise, the more idiomatic way to write your foreach loop would be to declare $key within the loop: 

    foreach my $key (keys %data) {
    print "$key,$data{$key}\n";
}

    [download]
[reply]
[d/l]
[select]
Re^4: How to Map a scalar to a key that is an array?
by 1nickt (Canon) on Aug 02, 2019 at 13:37 UTC

    Hi,

    Using the data from your OP, the above code prints: 

    arn:aws:iam::12345678901:role/Role2-Role2,"Alexa for Business"
arn:aws:iam::11111111111:role/ADFS-MyRoleName,"Alexa for Business"

    [download]
    Is that really what you wanted? Your original post stated

    "I would like to create a hashmap so I can count the # of items under each of the 'arn'"

    • Your split() call is throwing away everything but the first line in each section. If you want all remaining lines, use the third argument of split: my ($key, $data) = split(/\n/, $line, 1).
    • Calling your results hash by the same name you call the value to be added to it, is unnecessary complication of your life, even if Perl can handle it.

    If what you want is what you said you want, I would use: 

    use strict;
use warnings;
use feature 'say';
use List::Util 'max';

my %count;

local $/ = "arn:aws:iam::";

while (my $line = <DATA>) {
    chomp $line;
    $line =~ s!$/!! if $. == 1;
    next if $line eq '';

    my ($key, @values) = split(/\n/, $line);
    $count{$key} = scalar @values;
}

my @keys = keys %count;
my $longest = max map { length } @keys;

for my $key (sort @keys) {
    say sprintf("%-${longest}s : %3d", $key, $count{$key});
}
__DATA__
arn:aws:iam::11111111111:role/ADFS-MyRoleName
"Alexa for Business"
"AWS Certificate Manager"
"AWS Certificate Manager Private Certificate Authority"
"AWS Amplify"
"Manage - Amazon API Gateway"
"AWS App Mesh"
"Amazon AppStream 2.0"
"AWS AppSync"
"Amazon Athena"
"AWS Auto Scaling"

arn:aws:iam::12345678901:role/Role2-Role2
"Alexa for Business"
"AWS Certificate Manager"
"AWS Certificate Manager Private Certificate Authority"
"AWS Amplify"
"Manage - Amazon API Gateway"
"Application Auto Scaling"
"AWS App Mesh"
"Amazon AppStream 2.0"
"AWS AppSync"

    [download]
    Output: 
    11111111111:role/ADFS-MyRoleName :  10
12345678901:role/Role2-Role2     :   9

    [download]

    Hope this helps!


    The way forward always starts with a minimal test.
[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom