in reply to Mapping data structures through external source

That's exactly the case where Data::Diver is helpful! 
#!/usr/bin/perl
use warnings;
use strict;

use Data::Diver qw{ Dive };

my $external_structure = { ... };

my %format = (product_id     => ['id'],
              price_excl_vat => [qw[ data price ]],
              unit_qty       => [qw[ data unit_info qty ]]);  # (1)

my $internal_structure = {};
for my $key (keys %format) {
    $internal_structure->{$key}
        = Dive($external_structure, @{ $format{$key} });
}

use Data::Dumper; print Dumper $internal_structure;

[download]

(1) Note that the second element of the path is unit_info, not just unit.

map{substr$_->[0],$_->[1]||0,1}[\*||{},3],[[]],[ref qr-1,-,-1],[{}],[sub{}^*ARGV,3]

Replies are listed 'Best First'.
Re^2: Mapping data structures through external source
by Aldebaran (Curate) on Aug 02, 2019 at 19:33 UTC
    That's exactly the case where Data::Diver is helpful!

    This is my first exposure to Data::Diver, and I'm impressed and happy to put this in my bag of various scripts:

    $ ./1.diver.pl 
$VAR1 = {
          'product_id' => 'ABC123',
          'unit_qty' => '1',
          'price_excl_vat' => '1000'
        };
$ cat 1.diver.pl

    [download]
    #!/usr/bin/perl
use 5.016;
use warnings;
use Data::Diver qw{ Dive };
use Data::Dumper;

my $external_structure = {
  'name' => 'Test product',
  'id'   => 'ABC123',
  'data' => {
    'enabled'     => '1',
    'internal_id' => '',
    'urls'        => {
      'main_url' => ''
    },
    'price'     => '1000',
    'unit'      => 'ST',
    'unit_info' => {
      'qty'  => '1',
      'gtin' => '1234567890'
    }
  }
};

my %format = (
  product_id     => ['id'],
  price_excl_vat => [qw[ data price ]],
  unit_qty       => [qw[ data unit_info qty ]]
);    # (1)

my $internal_structure = {};
for my $key ( keys %format ) {
  $internal_structure->{$key} =
    Dive( $external_structure, @{ $format{$key} } );
}

print Dumper $internal_structure;

__END__
$

    [download]
    Note that the second element of the path is unit_info, not just unit.

    Well noted. This points out the problem of whether to "fix" the original post. If OP does, then both of our posts might need "fixing" too. My preference is to leave the warts on the original post.

[reply]
[d/l]
[select]
Re^2: Mapping data structures through external source
by DreamT (Pilgrim) on Aug 05, 2019 at 07:43 UTC
    Thank you for your reply (and thank you for the note regarding the structure error - Fixed now).
    However, I'm in a position where I can't install Data::Diver (or any other external module for that matter). Do you have any "core Perl" solutions to suggest?
[reply]
      However, I'm in a position where I can't install Data::Diver (or any other external module for that matter).

      Yes, even you can use CPAN! I strongly suggest to take some time to look into e.g. local::lib or maybe App::FatPacker.

      Having said that, I've written some custom "diver" type code here and here.

[reply]

In Section Seekers of Perl Wisdom