The problem is in the postfix increment operation.

Use an if block (or similar) instead to avoid conditional dependence on $H_count under the increment operator. Others will be able able to explain the reasons in detail.

use strict;  
use warnings;  
my %H_list;  

open my $H_list, '<', 'listH.txt' or die "Cannot open listH.txt: $!"; 
+ 
while (my $line = <$H_list>) { 
    chomp $line; 
    $line =~ s/\r//g; # removes windows CR characters 
    $line =~ s/\s+$//; # removes trailing white spaces 
    $H_list{$line} = 1 
}  
close $H_list;  

my ($L_count, $H_count); 
open my $L_list, '<', 'listL.txt' or die "Cannot open listL.txt: $!"; 
+ 
while (<$L_list>) {  
    chomp;  
    s/\r//; 
    s/\s+$//; 
    $L_count ++; 
    print;
    if (exists $H_list{$_}) {
        $H_count ++;
        print ' On List H';
    }
    print "\n";  
} 

print "List L UNIQUES: $L_count; FLAGGED From List H: $H_count \n";
[download]

UPDATE: See for example node 776720.

The reason of the problem is that when you run:

$H_count ++ and ...
[download]

for the first time, the post increment operator sets $H_count to 1 and returns 0, i.e. a false value. Therefore, the statement following the and operator is not executed. The next time you run the same post-increment statement, it will return 1 (and subsequently other true values) and it will work fine as shown in the following test under the Perl debugger:

  DB<1> $h++ and print "foo";

  DB<2> $h++ and print "foo";
foo
[download]

This would work fine with the pre-increment operator:

  DB<3> ++$i  and print "foo";
foo
[download]

The solution suggested by swl is probably better because there is no hidden surprise in it.

As a side comment, please note that in these two code lines:

    $line =~ s/\r//g; # removes windows CR characters 
    $line =~ s/\s+$//; # removes trailing white spaces
[download]

the first line isn't useful, because the second code line will remove all trailing white spaces, including the \r Windows CR character.

the first line isn't useful, because the second code line will remove all trailing white spaces, including the \r Windows CR character.

While I take your point, they are not entirely equivalent. The difference is that the first line removes all the \r characters wherever they appear in the line. The second does not do that.

use strict;
use warnings;

use Test::More tests => 2;

my $have = "foo\rbar\rbaz\r\n";
my $want = "foobarbaz";
$have =~ s/\s+$//;
isnt $have, $want, 'Not all carriage returns removed';
$have =~ s/\r//g;
is $have, $want, 'All carriage returns removed';
[download]

I've spent far too much time over the years fighting poorly-formed, non-compliant, randomly-encoded data originating from Windows to assume anything about the quality of such data. YMMV.