The IO::Compress::Zip docs say you can pass a reference to a scalar to get the data written there. This will use more memory, but here's an example that includes the Content-Length header:

#!/usr/bin/perl
use warnings;
use strict;
use CGI::Simple;
use IO::Compress::Zip qw/$ZipError/;
use Encode qw/encode/;

my @lines = (qw/ Hello World Foo Bar /, "\N{U+1F42A}");
my $CRLF = "\r\n";
my $encoding = "UTF-8"; # or maybe "CP1252" for Windows

my $zipdata;
my $z = IO::Compress::Zip->new(\$zipdata,
    Name => "Filename.txt" )
        or die "zip failed: $ZipError\n";
for my $line (@lines) {
    $z->print( encode($encoding, $line.$CRLF,
        Encode::FB_CROAK|Encode::LEAVE_SRC) );
}
$z->close();

my $q = CGI::Simple->new();

print $q->header( -type => 'application/zip',
    -Content_Disposition => qq{attachment; filename="Download.zip"},
    -Content_Length => length($zipdata) );

binmode STDOUT;  # just to play it safe
print $zipdata;
[download]

As for the code you showed, I'd strongly recommend proper indentation (perltidy can help with that). I also have the feeling that you might not be using strict and warnings, or that you're using too many global variables (e.g. $statement). And a nitpick: I wouldn't use $CRLF for outputting the HTTP headers, "\n" is enough, every webserver I've worked with understands that (but really, you should be using a module to write the headers anyway, as I showed above).

Also, as I mentioned, you can save the memory of the @resp array by merging those two loops. For example:

$z->print( encode( $encoding, "RECORD#\tREVISION#\tBOOK#\tCHAP#\tVERSE
+#\tTEXT, AS EDITED BY: $curdate $curtime (Pacific Time)$CRLF", Encode
+::FB_CROAK|Encode::LEAVE_SRC ) );
while ( ( $recnum, $revnum, $book, $chap, $verse, $text ) = $quest->fe
+tchrow_array() ) {
    $z->print( encode( $encoding, "$recnum\t$revnum\t$book\t$chap\t$ve
+rse\t$text$CRLF", Encode::FB_CROAK|Encode::LEAVE_SRC ) );
}
[download]

If any of the fields you're outputting could possibly contain tabs, you might want to switch to Text::CSV for proper handling of all of those complexities.

Beautiful! The following code is now in place and, having tested it with both Windows and Mac, it is working exactly as desired. Thank you so much for taking time to help with this. I have learned a few things.

None of the fields should ever contain tabs, so that should be no issue. I always use strict, but only use warnings while troubleshooting. It's presently commented out to save space in the log files (when working with UTF8, wide character warnings seem to appear for no reason at times, when everything is working properly, and sometimes I get the uninitialized errors that are also extraneous--and the logs simply aren't monitored often enough to make filling them with such errors useful). For what it's worth, when the script with this subroutine is run, the script is adding a "wide character" error to the error log even with warnings turned off, despite the fact that everything is working beautifully, and the zip file that is created contains perfect text in an Asian language. The error comes from having Asian text in one of the HTML headings for the page, even though the "use utf8;" pragma is in place. To avoid it I'd probably need to convert that text to HTML-entities which makes it totally unreadable in my code, and ugly. I'd rather get useless warnings.

sub exportdatabase { 
#INCOMING GLOBAL VARS: $statement, $db_export_file,
# $cur_date, $cur_time, $OS, $table, $quest

fork: {

my ($recnum,$revnum,$book,$chap,$verse,$text) = '';
my @resp     = ();
my $encoding     = "UTF-8";
my $zipdata     = '';
my $CRLF     = "\n";
my $zipfile     = "$db_export_file.zip";
my $q = CGI::Simple->new();
my $z = IO::Compress::Zip->new(\$zipdata,
    Name => "$db_export_file" )
    or die "zip failed: $ZipError\n";

    if ($OS eq "Windows") { 
        $CRLF = "\r\n";
    } 

    $statement = qq| SELECT a.RecordNum, a.RevisionNum, a.Book, a.Chap
+ter, a.Verse, a.Text from $table a INNER JOIN (SELECT RecordNum, max(
+RevisionNum) RevisionNum FROM $table GROUP BY RecordNum) b USING (Rec
+ordNum,RevisionNum); |;

    &connectdb('exportdatabase');

    $z->print( encode( $encoding, "RECORD#\tREVISION#\tBOOK#\tCHAP#\tV
+ERSE#\tTEXT, AS EDITED BY: $curdate $curtime (Pacific Time), EXPORTED
+ IN $OS FORMAT$CRLF", Encode::FB_CROAK|Encode::LEAVE_SRC ) );
    while ( ( $recnum, $revnum, $book, $chap, $verse, $text ) = $quest
+->fetchrow_array() ) {
        $z->print( encode( $encoding, "$recnum\t$revnum\t$book\t$chap\
+t$verse\t$text$CRLF", Encode::FB_CROAK|Encode::LEAVE_SRC ) );
    }
    $z->close();

    print $q->header( -type => 'application/zip',
    -Content_Disposition => qq{attachment; filename="$zipfile"},
    -Content_Length => length($zipdata) );

    binmode STDOUT;  # just to play it safe
    print $zipdata;

} # END fork
} # END SUB exportdatabase
[download]

Glad to help!

when working with UTF8, wide character warnings seem to appear for no reason at times, when everything is working properly, and sometimes I get the uninitialized errors that are also extraneous ... I'd rather get useless warnings.

While I agree that when building strings for output, the "uninitialized" warnings can often be turned off (no warnings 'uninitialized';, limited to the scope where it's needed), the UTF-8 / wide character warnings are actually useful and are pointing to the fact that something is wrong, even if it may appear to be "working beautifully". For example, at my console, I can do this:

$ perl -le 'print "\N{U+263A}"'
Wide character in print at -e line 1.
☺

Since the smiley was printed correctly, it appears to be working. But the fact that it worked is only because my terminal's encoding happened to match the encoding Perl used. So if you're getting these warnings, likely you've still got an encoding issue somewhere, and it might come back to bite you later. It would probably be helpful if you can reduce the issue down to an SSCCE, then you could post it as a new question here to get help with it.

even though the "use utf8;" pragma is in place

The utf8 pragma only tells Perl that the source code is encoded in UTF-8. It doesn't change the encoding of STDIN, STDOUT, etc. - for that, you could use the open pragma, e.g. use open qw/:std :utf8/;.

> my ($recnum,$revnum,$book,$chap,$verse,$text) = '';

That only initializes the first var, try this instead:

my ($recnum,$revnum,$book,$chap,$verse,$text) = ('') x 6;

TIMTOWTDI

my $CRLF = $OS eq 'Windows' ? "\r\n" : "\n";

use Socket ':crlf';
my $CRLF = $OS eq 'Windows' ? CRLF : LF;
[download]