Here's another approach:

c:\@Work\Perl\monks>perl -wMstrict -le
"print qq{perl version $]};
 ;;
 my @strings = (
   'Link:1625 housing Link:2004',
   'Link:638 92-5000|Link:63892-5070',
   );
 ;;
 my $rx_numeric = qr{ \d+ (?: - \d+)? }xms;
 ;;
 for my $str (@strings) {
   my @matches = $str =~ m{ Link : ($rx_numeric (?: \s+ $rx_numeric)?)
+ }xmsg;
   print qq{'$str' -> }, map qq{'$_' }, @matches;
   }
"
perl version 5.008009
'Link:1625 housing Link:2004' -> '1625' '2004'
'Link:638 92-5000|Link:63892-5070' -> '638 92-5000' '63892-5070'
[download]

Update: I often find it prudent to add an extra element of safety by using boundary assertions in data field regexes. So  $rx_numeric might be better defined as (tested)
    my $rx_numeric = qr{ (?<! \d) \d+ (?: - \d+)? (?! \d) }xms;
See  (?<!pattern) (?!pattern) in Extended Patterns in perlre.

Edited about 30 secs after posting - the regex does not work.

Your regex is not delimited. Using the explicit match (m//) notation might help clarify things.

It also needs the g modifier to match all cases.

my $str = 'Link:1625 housing Link:2004';
my @matches = ( $str =~ m/(?:link:) [^\s\|]+/g );
[download]

See perlretut for more examples.

(I have not tested that the regex works, though).

Try this for the regex. It works with the test data provided.

my @matches = ( $str =~ m/\|?Link:([\s0-9-]+)/g );
[download]

use strict;
use warnings;
use feature 'state';
use Test::More tests => 2;

my @scenarios = (
  #     String                                  Expected match
  ["Link:1625 housing Link:2004",      ['1625',        '2004'      ]],
  ["Link:638 92-5000|Link:63892-5070", ['638 92-5000', '63892-5070']],
);

my $pattern = qr/\d+ (?: [- ]\d+ )* /x;
    
foreach my $scenario (@scenarios) {
    state $i = 1;
    my $str = $scenario->[0];
    my @matches = $str =~ m/Link: ($pattern)/gx;
    is_deeply( \@matches, $scenario->[1], "Scenario $i");
    $i++;
}
[download]

OUTPUT:
1..2
ok 1 - Scenario 1
ok 2 - Scenario 2
[download]