mis has asked for the wisdom of the Perl Monks concerning the following question:

Hi Perlmonks,

Is if possible to have a string interpreted as a literal without pre-escapting in a regex. Consider: 

#!/opt/local/bin/perl
my $a = "Tick F***ing Tock";
my $b = "Friday night at 11:30pm the start of a new series, 'Tick F***
+ing Tock' explores...";

if ($b =~ /$a/)
{
  print "..do something..\n";
}

[download]
This will return: 
$ ./t.pl
Nested quantifiers in regex; marked by <-- HERE in m/Tick F** <-- HERE
+ *ing Tock/ at ./t.pl line 5.

[download]
Of course this will work: 
#!/opt/local/bin/perl
my $a = "Tick F***ing Tock";
my $b = "Friday night at 11:30pm the start of a new series, 'Tick F***
+ing Tock' explores...";

$a =~ s/([\(\)\[\]\{\}\\\*\?\.\$\^\@\!\&])/\\$1/g;

if ($b =~ /$a/)
{
  print "..do something..\n";
}

[download]
Result: 
$ ./t.pl
..do something..

[download]
However there will result in a long list of escapes to make parsing safe as '$a' in my script is dynamic and not fixed like in this example... Also there will no doubt be a significant performance hit considering the number of times I'd be looping over the regex...

Thanks in advance.

Replies are listed 'Best First'.
Re: Switch/Format to not interpret metacharacters in regex?
by tybalt89 (Monsignor) on Dec 04, 2019 at 01:36 UTC
[reply]
[d/l]
      Thank you! (knew it was there somewhere but couldn't spot it reading perlre.. hangover doesn't help. :D )
[reply]
Re: Switch/Format to not interpret metacharacters in regex?
by GrandFather (Saint) on Dec 04, 2019 at 01:47 UTC

    If what you really want to do is just look for one string in another than index is the better tool:

    use strict;
use warnings;

my $match = "Tick F***ing Tock";
my $str = "Friday night at 11:30pm the start of a new series, 'Tick F*
+**ing Tock' explores...";

if (-1 != index $str, $match) {
  print "..do something..\n";
}

    [download]

    If you really want to use a regex then use quotemeta to do the quoting for you:

    use strict;
use warnings;

my $match = "Tick F***ing Tock";
my $str = "Friday night at 11:30pm the start of a new series, 'Tick F*
+**ing Tock' explores...";

$match = quotemeta $match;

if ($str =~ $match) {
  print "..do something..\n";
}

    [download]
    Optimising for fewest key strokes only makes sense transmitting to Pluto or beyond
[reply]
[d/l]
[select]
      I'm actually fixing someone elses code, based on the actual code the fix might be as simple as: 
      if (lc($b) eq lc($a))
{
  print "do something...\n";
}

      [download]
      However the first answer (using /\Q$a\E/) has immediately fixed the issue and knowing the data it will be a permanent fix for the issue... it also taught me something that I probably have come across in the past... 20+years working with perl and I still learn something new every so often... :)

      Thanks, all.
[reply]
[d/l]
[select]

        G'day mis,

        Welcome to the Monastery.

        Two quick points:

        • $a and $b are special variables which I'd recommend avoiding except for their special purposes. See perlvar: $a for more information.
        • Instead of using lc (or uc) consider fc. Note that you'll need Perl 5.16 for that.

        — Ken

[reply]
[d/l]
[select]
Re: Switch/Format to not interpret metacharacters in regex?
by Laurent_R (Canon) on Dec 05, 2019 at 17:27 UTC
    See also the built-in quotemeta function (which does something very similar to \Q ... \E).
[reply]
[d/l]
      See also the built-in quotemeta function (which does something very similar to \Q ... \E).

      Not only similar. quotemeta is the function implementing the \Q escape, according to quotemeta.

      Alexander

      --
      Today I will gladly share my knowledge and experience, for there are no sweeter words than "I told you so". ;-)
[reply]
[d/l]
[select]
        Yes, afoken++, you're right. I did not want to say that they are identical, because they have a different calling syntax, but, yes, they do the same thing.
[reply]

Back to Seekers of Perl Wisdom