Ahhh, this clarifies a lot. Most of the answers are in the documentation, it's just so hard to keep track of all of it...

But it still does not explain why scalar(sort @a) returns undef. If sort @a returns a list, and a list in scalar context gets you the last value... or does it only apply to named lists?

Thank you all for your responses. This thread has been very enlightening for me.

--ZZamboni

I think you might be missing one of the finer points of perl.

Functions can return completly different value depending on what context they are called in. sort does not always return a list, it usually does. If sort is called is a scalar context then the function returns undef. It does not return a list if called in scalar context. So the scalar function is not placing the return value of sort in scalar context it is placing the the actual function call in scalar context.

Here is some code for demonstration:
This is what Russ was refering to

$scalar = (5,10,15,20);
print $scalar, "\n";
[download]

Results:
20

This creates a function which will return different values depending on the context that the function was called in:

sub get_list
{
    # return a list if a list is wanted, else 
    # return the string
    return wantarray ? (5,10,15,20) : "SCALAR CALL";
}
[download]

And to see this code in action:

$scalar = get_list();
print $scalar, "\n";

@array = get_list();
print join(" ", @array), "\n";
[download]

Results:
SCALAR CALL
5 10 15 20

And similarly:

print scalar(get_list()), "\n";
print join(" ", get_list()), "\n";
[download]

Results:
SCALAR CALL
5 10 15 20

Hopefully this helps.