%myHash = &makeHash($key, $val, \%myHash)

Skip the left part and you are fine, no need to reset the hash. :)

 makeHash($key, $val, \%myHash)

update

Your makeHash() is seriously broken.

Please have a look at perlref to understand how references work.

update

my $subHashRef = shift @_; 
$subHashRef->{$key} = $val;
[download]

    my($key);
    my($val);
    my(%subHash);
    $key = shift @_;
    $val = shift @_;
    %subHash = %{shift @_};
[download]

Dear Bill, thank you your solution works just fine! I am learning Perl 5.8 but since I am doing it on my own I lack most of the best tricks for efficient scripts. My best wishes of happy new year, G

G, You are doing a good job learning the basic concepts. Your style needs a great deal of improvement. You should find all of the other replies helpful in this respect. Happy new year to you too.
Bill

This is a first rewrite of your code, keeping your code architecture but correcting a couple of mistakes and simplifying the code. We are down to 22 code lines:

use strict;
use warnings;
use Data::Dumper;

my %myHash;
my @array = qw( sean connery george lazemby roger moore timothy dalton
+ pierce brosnan );
print("The array is: @array\n");

for my $i (0..4) {
    print("\nElement number $i\n");
    my ($key, $val) = splice @array, 0, 2;;
    print("The key is: $key\nThe value is: $val\n");
    populateHash($key, $val, \%myHash);
    print"The hash at cycle $i is: ", Dumper \%myHash;
}
print Dumper \%myHash;
    
sub populateHash {
    my ($key, $val, $hashref) = @_;
    print "In the function, the key is $key and the value is $val\n";
    $hashref->{$key} = $val;
}
[download]

use strict;
use warnings;
use Data::Dumper;

my %myHash;
my @array = qw( sean connery george lazemby roger moore timothy dalton
+ pierce brosnan );

for my $i (0..4) {
    my ($key, $val) = splice @array, 0, 2;;
    $myHash{$key} = $val;
}
print Dumper \%myHash;
[download]

$ perl populate_hash.pl
$VAR1 = {
          'timothy' => 'dalton',
          'sean' => 'connery',
          'roger' => 'moore',
          'pierce' => 'brosnan',
          'george' => 'lazemby'
        };
[download]

... populating the hash really takes just 1 line of code ...

E.g., for the given example data of the OP:

c:\@Work\Perl\monks>perl -wMstrict -MData::Dump -le
"my @array = qw( sean connery george lazenby roger moore timothy dalto
+n pierce brosnan );
 my %myHash = @array;
 dd \%myHash;
"
{
  george  => "lazenby",
  pierce  => "brosnan",
  roger   => "moore",
  sean    => "connery",
  timothy => "dalton",
}
[download]

Sure, you're right. I wanted to start keeping the OP's general architecture while fixing its defects, and then to simplify it in two steps. I originally thought of completing my post with a direct assignment as you did, but I forgot to do it when completing the post. Thanks for doing it. This is of course the easiest solution.

I prefer the OP's approach. Functions should return their results through the return rather than through a reference. I believe that most of his additional code is code that he added to debug the problem himself before he posted. If so, he should be commended. Your use of Dumper and your attention to scope are details he should learn.
Bill

> Functions should return their results through the return rather than through a reference.

Plz be aware that passing and returning hashes as lists can cause much useless overhead, if the original hash has to be overwritten.

Cheers Rolf

_{(addicted to the Perl Programming Language and ☆☆☆☆ :)}

Functions should return their results through the return rather than through a reference.

Hi Bill,

Yes, I agree in general and often try to write "pure" functions, but I am at the same time generally quite reluctant at the idea of passing around many times a data structure, because this is quite inefficient, as already pointed out by LanX. (Granted, it does not really matter with such small array and hash, but I am usually manipulating fairly large data structures.)

Anyway, I would not do it the way I described in my first code sample, which aimed at keeping the general code structure of the OP, which was passing a reference to the hash. BTW, this is not very useful here in view of the fact that the hash is in fact a global variable.

If I wanted to populate the hash in a separate function (which is not really needed in such a simple case, but I am often doing this type of thing when populating the hash is more complicated and requires, for example, to read from one or several file(s) and process the content before actually storing keys and values into the hash), I would call that function only once and pass to it a reference to the array and then return the hash or, when the data is large, return a reference to the hash. Something along these lines:

use strict;
use warnings;
use Data::Dumper;

my @array = qw( sean connery george lazemby roger moore timothy dalton
+ pierce brosnan );
my $hash_ref = populate_hash(\@array);
print Dumper $hash_ref;

sub populate_hash {
    my $array_ref = shift;
    my %hash;
    for (0..4) {
        my ($key, $val) = splice @$array_ref, 0, 2;
        $hash{$key} = $val;
    }
    return \%hash;
}
[download]

But, again, this is only for the sake of argument: for such a simple case, I would not even use a separate function, and the easiest solution is the one provided by AnomalousMonk.

Dear Bill,
you are right: all the text I have used herein was just for debugging. The actual function I would like to create would just populate a given hash when called in different points within the main scripts. And at the moment I have no idea what Dumper is...
G

Dear Lauren,
thank you for your reply, I will need some times to digest it.
Meanwhile, my best wishes of happy new year,
G