G'day WingedKnight,

Welcome to the Monastery.

When in doubt, it's often a good idea to find out how Perl is seeing your code with B::Deparse.

$ perl -MO=Deparse,-p -e 'print "foo, " . (1 ? "yes" : "no") . " bar";
+'
print('foo, yes bar');
-e syntax OK
[download]

$ perl -MO=Deparse,-p -e 'print (1 ? "yes" : "no") . " bar";'
(print('yes') . ' bar');
-e syntax OK
[download]

"Why isn't " bar" getting appended to the output in the second case?"

Because it's getting appended to the return value from print.

$ perl -e '$x = print "foo, " . (1 ? "yes" : "no") . " bar"; print "\n
+$x\n"'
foo, yes bar
1
[download]

$ perl -e '$x = print (1 ? "yes" : "no") . " bar"; print "\n$x\n"'
yes
1 bar
[download]

Of course, you should start all your code with:

use strict;
use warnings;
[download]

In this case, you would have received warnings:

$ perl -e 'use strict; use warnings; print (1 ? "yes" : "no") . " bar"
+;'
print (...) interpreted as function at -e line 1.
Useless use of concatenation (.) or string in void context at -e line 
+1.
yes
[download]

See "perlintro: Safety net".

Try

print +(1 ? 'yes' : 'no') . ' bar';
[download]

And then read the top of perlfunc

Also, try it with commas instead of concatenation and you won't need parentheses and you won't have this problem:

print 'foo, ', 1 ? 'yes' : 'no',  ' bar';
[download]

print 1 ? 'yes' : 'no',  ' bar';
[download]

my $call_resp = print(1 ? 'yes' : 'no)   .   'bar';  # yes
print "\nprint() function returned: $call_resp\n";   # \nprint() funct
+ion returned: 1bar\n
[download]

print returns a true value on success, and a false value if it failed. The parenthesis, the way you're using them, become the arg list for print. So you're asking Perl to print 'yes', and then to append 'bar' to the return response from print. This is almost equivalent, and may help explain what's happening:

(print 1 ? 'yes' : 'no') . 'bar';
[download]

A common disambiguation is +(...). I wasn't sure it would be appropriate when concatenating later, but I just verified that it works fine:

print +(1 ? 'yes' : 'no') . "bar\n"; # yesbar\n
[download]