For one thing your sample file has no ":" characters in it so your split isn't doing what you want; use my( $k, $v ) = split( /\s+/, $line ) instead.

$ perl -E '$_=qq{GeneName    GeneType};my($foo,$bar)=split(/:/,$_);say
+ qq{foo: $foo\nbar: $bar}'
foo: GeneName    GeneType
bar:
$ perl -E '$_=qq{GeneName    GeneType};my($foo,$bar)=split(/\s+/,$_);s
+ay qq{foo: $foo\nbar: $bar}'
foo: GeneName
bar: GeneType
[download]

That aside, your commented out printing code should have been fine. My guess is since your split wasn't working the way you expected you went and tried to do what you've got now, which just doesn't make sense (walk over every item in the hash, and for each item print a list of all the keys in the hash). Alternately consider using Data::Dumper or YAML::XS or the like to print out the contents.

$ perl -E '%hash = qw( a b c d ); while( my( $k, $v ) = each %hash ) {
+ say qq{$k => $v}; }'
c => d
a => b
[download]

G'day shabird,

Welcome to the Monastery.

You've posted your input data twice. Working past that, is it really double-spaced as you've shown? The output from your 'print $line,"\n";' would have been useful for us; however, you've commented that out.

There's another bigger problem. You said "its not printing anything". The code you posted would have printed something like:

Global symbol "@keys" requires explicit package name ...
Execution ... aborted due to compilation errors.
[download]

For future reference, please

• take more care when posting input data,
• post the actual code you are running, and
• provide us with the exact output you get (even if that's only error or warning messages).

If you had made a mistake by trying to split on non-existent colons, you still would have got the keys but the values would have been all undef. Here's a quick example:

$ perl -e '
    my $x = "MIR200B miRNA";
    my %h;
    my ($k, $v) = split /:/, $x;
    $h{$k} = $v;
    use Data::Dumper;
    print Dumper(\%h);
'
$VAR1 = {
          'MIR200B miRNA' => undef
        };
[download]

Given there's so many question marks over the data and the code, it's difficult to advise you. The following may be close to what you were trying achieve; or, at least, provide some insight into how you might proceed.

#!/usr/bin/env perl

use strict;
use warnings;

my %data;

while (<DATA>) {
    next if $. == 1;
    chomp;
    next unless length;
    my ($k, $v) = split;
    $data{$k} = $v;
}

# To test result
use Data::Dumper;
print "*** Hash ***\n";
print Dumper(\%data);
print "*** Keys ***\n";
print "$_\n" for keys %data;
print "*** Values ***\n";
print "$_\n" for values %data;

__DATA__
GeneName    GeneType

APOL4   protein_coding

CYP2C8  protein_coding

NAALADL2    protein_coding

NANOS3  protein_coding

C20orf204   protein_coding

MIR429  miRNA

MIR200A miRNA

MIR200B miRNA
[download]

Output:

*** Hash ***
$VAR1 = {
          'NANOS3' => 'protein_coding',
          'C20orf204' => 'protein_coding',
          'APOL4' => 'protein_coding',
          'MIR429' => 'miRNA',
          'NAALADL2' => 'protein_coding',
          'MIR200B' => 'miRNA',
          'MIR200A' => 'miRNA',
          'CYP2C8' => 'protein_coding'
        };
*** Keys ***
NANOS3
C20orf204
APOL4
MIR429
NAALADL2
MIR200B
MIR200A
CYP2C8
*** Values ***
protein_coding
protein_coding
protein_coding
miRNA
protein_coding
miRNA
miRNA
protein_coding
[download]

foreach my $key ( @keys) {
    print $key,"\n";
}
[download]

Beside the fact that your code doesn't compile, there is another issue with the while loop, keys resets the iterator so each starts from the first pair each time. Your loop basically means that while you get the first key/value pair, print all the keys; which is an infinite loop.

Fletch is probably right and you probably just got this frankencode while trying different ways to debug, but FYI you should avoid using keys or values inside a while(each) loop.

> you should avoid using keys or values inside a while(each) loop.

It's easier to always avoid each which is the advice I listen to.

map{substr$_->[0],$_->[1]||0,1}[\*||{},3],[[]],[ref qr-1,-,-1],[{}],[sub{}^*ARGV,3]