Hi, welcome to Perl, the One True Religion.

eq and ne do not work as the solution to a problem where '* could be anything.'

You need instead a solution where the string is compared against a pattern in which '* could be anything.' This is called a regular expression match. See perlretut for a tutorial.

You can also play with regular expressions and see what they are doing at https://regex101.com. Your case probably wants to use a regexp like

if ($entry3 !~ /${user_input}_ABC_\S*\.pdf/) { ... }
[download]

... but I would search for files using Path::Iterator::Rule myself.

use Path::Iterator::Rule;

...

my $rule = Path::Iterator::Rule->new;

$rule->file->not_name( qr/${user_input}_ABC_\S*\.pdf/ );
my $next = $rule->iter( $doc_dir );

while (defined( my $file = $next->() )) { ... }
[download]

Hope this helps!

If you don't want to follow the advice of others concerning Path::* (and there are other modules to do similar things) and want to roll your own regex, be warned that regex be tricky.

For instance, the  qr/${user_input}_ABC_.*pd/ regex used here fails (i.e., accepts as valid) the xyzabc_ABC_hipdip filename. (There's also the problem that the logical sense of the test is wrong, but that's minor.)

Line-end anchors  \A \z can be useful here, as can  \Q \E metaquoting escape sequences to guard against regex metacharacters included in the  $user_input portion of the filename. E.g.:

c:\@Work\Perl\monks>perl -wMstrict -le
"my $user_input = 'ab+c';
 my $excluded = qr{ \A \Q$user_input\E _ABC_ .* [.] pdf \z }xms;
 ;;
 FILE:
 foreach my $file (qw(
   ab+c_ABC_something.pdf  ab+c_ABC_anything.pdf  ab+c_ABC_.pdf
   xab+c_ABC_.pdf  ab+c_ABC_.pdfx  xab+c_ABC_.pdfx
   abc_ABC_something.pdf  abc_ABC_anything.pdf  abc_ABC_.pdf
   abc  _.pdf  xyzabc_ABC_hipdip  foobar
   )) {
   next FILE if $file =~ $excluded;
   print qq{'$file' is not excluded};
   }
"
'xab+c_ABC_.pdf' is not excluded
'ab+c_ABC_.pdfx' is not excluded
'xab+c_ABC_.pdfx' is not excluded
'abc_ABC_something.pdf' is not excluded
'abc_ABC_anything.pdf' is not excluded
'abc_ABC_.pdf' is not excluded
'abc' is not excluded
'_.pdf' is not excluded
'xyzabc_ABC_hipdip' is not excluded
'foobar' is not excluded
[download]

Note also that thorough testing is wise in case you are using a regex approach; see Test::More and its ilk.

Please see perlre, perlretut, and perlrequick.

use strict;
use warnings;

my $user_input = "abc";
my $regex = qr/${user_input}_ABC_.*pd/;

foreach my $file  (qw (abc abc_ABC_something.pdf  abc_ABC_anything.pdf
+))
{   
   next unless $file =~ /$regex/;
   print "$file is valid\n";
}

__END__
abc_ABC_something.pdf is valid
abc_ABC_anything.pdf is valid
[download]

Andy Lester's ack will do that quite nicely.

To search files NOT named ".lst" for the string ".txt":

ack "--ignore-file=match:\.lst" "\.txt"
[download]

Or in your case something like

ack "--ignore-file=match:<user stuff here>_ABC_.*\.pdf" "\.txt"
[download]

Yes, it's coded in perl.

Yes, I'm on Windows. For *nix use 's in place of "s.

Use a regex of some sort...

# Untested for file name with space.
$base_name =~ m{ \A $input some-fixed-string .*? [.]pdf \z }x;
[download]

I tried this and is working. Thank you. However, when i use -e to test it, seems not working. Could you pointed me out?

 
if (-e m{ \A $input some-fixed-string .*? [.]pdf \z }x}
..
}
[download]

You are not checking for existence of a file path, but the result of regex match against $_.

I think you would be better off (for some definition of "better") with Path::* solution suggested earlier instead of rolling a solution on your own. Also, please do the RTFM.