G'day jsteng,

To the best of my knowledge, you cannot do this with Tk::Entry; however, you can code this functionality with Tk::Text.

The following code is fully functional. It shows how to set up the pseudo-entry widget (note the initial text has no spaces; just 12345). The "Latest Entry" button will retrieve the full, possibly edited, text (note the chomp) and update the display above.

#!/usr/bin/env perl

use strict;
use warnings;

use Tk;

my $mw = MainWindow::->new(-title => 'Vertical Entry');
$mw->geometry('300x400+40+40');

my $string = '12345';
my $entry = $mw->Text(-width => 1, -wrap => 'char');
$entry->pack(-fill => 'y', -side => 'left');
$entry->insert('1.0', $string);
$mw->Label(-textvariable => \$string)
    ->pack(-fill => 'x', -side => 'top');
$mw->Button(-text => 'Latest Entry', -command => sub {
    chomp($string = $entry->get('1.0', 'end'))
})
    ->pack(-fill => 'x', -side => 'top');
$mw->Button(-text => 'Exit', -command => sub { exit })
    ->pack(-side => 'bottom');

MainLoop;
[download]

It looks pretty weird to me, but that's what you asked for. :-)

use strict;
use warnings;
use Tk;

my $mw = MainWindow->new();

foreach (qw (1 2 3 4 5) )
{
    gen_entry_object ($mw, "Entry Window $_");
}    

MainLoop;


sub gen_entry_object
{
   my $mw = shift;
   my $entry = shift;
   
   $mw->Entry(-text => "$entry" )->pack;
}
[download]

Don't know how to rotate the characters, but...

use strict;
use warnings;

use Tk;
use Tk::Text;

my $MW = MainWindow->new;

my $text_frame = $MW->Frame->pack;

my $v_text = $text_frame->Text(
    qw(-relief flat  -width 1  -height 10  -wrap char)
    )->pack(qw(-side left));

my $xy_text = $text_frame->Text(
    qw(-relief flat  -width 20  -height 10  -wrap word)
    )->pack(qw(-side left));

$v_text->insert('1.0', '12345');

$xy_text ->insert('1.0', <<"EOT");
now is the time
the rain in spain
how now brown cow
EOT

$v_text->insert('end', 'abc');

$xy_text ->insert('end', <<"EOT");
four score and seven
years ago...
EOT

MainLoop;
[download]

This code provides 5 vertical entry fields which can be edited (that's what you can do to an entry field as opposed to a label or a button). You press the 'Print Values' button to see the edited values of these entry windows. I omitted the pack() details which can specify width, etc and also wrap around if desired. Tweaking these details can be time consuming.

The main point here is whether or not I have the general idea of what you wanted?

use strict;
use warnings;
use Tk;
use Data::Dumper;

my $mw = MainWindow->new();

my @entry_refs;

foreach (qw (1 2 3 4 5) )
{
    push @entry_refs, create_entry_object ($mw, "Default Value is: $_"
+, );    
}

$mw->Button(-text => 'Print Values', -command => \&list_entries)->pack
+(); 

MainLoop;


sub list_entries
{
   print "\n";
   foreach my $ref (@entry_refs)
   {
      print "$$ref\n";
   }
}

sub create_entry_object
{
   my $window = shift;
   my $text_var = shift;
   
   $window->Entry(-textvar => \$text_var )->pack;
   return \$text_var;
}
[download]

Out of half curiosity, half boredom, and half fun, I tried to build a (very incomplete) vertical entry from a Label widget using newlines to get a vertical display.

#!/usr/bin/perl

use strict;
use warnings;
use Tk;

my $text = 'Vertical';
my $entry = 'Entry';

my $mw = MainWindow->new;
$mw->geometry( '+600+200' );
$mw->Label(-text => "Two\nVerticalEntry\nWidgets", -fg => 'blue',
  -font => 'courierbold 20',)->pack;
my $middle = $mw->Frame->pack;

verticalentry( $middle, \$text, 12, sub {print "left text: $text\n"},
  -side => 'left' );
my $updateright = verticalentry( $middle, \$entry, 12,
  sub {print "right text: $entry\n"}, -side => 'right' );

$middle->Frame(-width => 30)->pack;
$mw->Button(-text => 'Exit', -command => sub {$mw->destroy},
  )->pack( -side => 'bottom', -fill => 'x' );
$mw->Button(-text => 'Clear Right', -command => sub {$updateright->(''
+)},
  )->pack( -side => 'bottom', -fill => 'x' );

$mw->repeat( 400, sub { -M $0 < 0 and $mw->destroy } ); # file saved a
+fter run
MainLoop;
-M $0 < 0 and exec $0; # restart on editor save :)

sub verticalentry
  {
  my ($parent, $textref, $length, $command, @packargs) = @_;
  my $edit = $parent->Label(-width => 1,
    -relief => 'sunken', -borderwidth => 3,
    -font => 'courierbold 30')->pack( @packargs );
  my $update = sub
    {
    @_ and $$textref = shift;
    $edit->configure(-text => join "\n",
      split //, substr $$textref . ' ' x $length, 0, $length);
    };
  $update->();
  $edit->bind('<Enter>' => sub { $edit->focus } );
  $edit->bind('<Key>' => sub {
    my $key = $_[0]->XEvent->A;
    use Data::Dump 'dd'; dd $key;
    if( $key =~ /^[ -~]$/ )
      {
      length $$textref < $length and $$textref .= $key;
      }
    elsif( $key eq "\b" )
      {
      chop $$textref;
      }
    elsif( $key eq "\r" )
      {
      $command->();
      }
    $update->();
    } );
  return $update;
  }
[download]

If nothing else, it shows a way to get a vertical column of text :)

This example has two independent vertical entries just so I could be sure all the closure stuff worked correctly.