#!/usr/bin/perl
use warnings;
use strict;

my $line = "BOGUS PPI3_SYNY3 276 aa linear BCT 13-NOV-2019\n";

if (my ($bogus, $acids) = $line =~ /BOGUS\s+([A-Z0-9_]+) ([0-9]+ [a-z]
++)/) {
    print "bogus: $bogus\nNumber of acids: $acids\n"
}
[download]

Your code is unfortunately incomplete. How did you populate $noOfAcids? Also, $ in the second regex can't match after "aa", as the string doesn't end there. Note that $1 et al. are only changed after a successful match, so if the second regex doesn't match, the value of $1 keeps the value from the previous match.

It might be easier to split the line on white space and slice out the relevant items.

johngg@shiraz:~/perl/Monks$ perl -Mstrict -Mwarnings -E '
open my $inFH, q{<}, \ <<__EOD__ or die $!;
BOGUS PPI3_SYNY3 276 aa linear BCT 13-NOV-2019
__EOD__

chomp( my $line = <$inFH> );
close $inFH or die $!;

my( $bogus, $acids ) = ( split m{\s+}, $line )[ 1, 2 ];
say qq{Bogus                 : $bogus\nNumber of amino acids : $acids}
+;'
Bogus                 : PPI3_SYNY3
Number of amino acids : 276
[download]

I hope this is helpful.

I work with many space separated files and I agree that split is often the easiest way to go. I would recommend using the character form of the "split on whitespace" in this situation because it has the property of ignoring leading whitespace, as I demo at Re: But I want null values in my array. This is just one of many, "yeah but's" and exceptions that I've discovered over time.

Your second regex never matches which is why both are the same. As stated, here's a potential solution.

use strict;
use warnings;
use Test::More tests => 2;

my $content = 'BOGUS PPI3_SYNY3 276 aa linear BCT 13-NOV-2019';

$content =~ /^(BOGUS\s+\S+)/;
is $1, 'BOGUS PPI3_SYNY3';

$content =~ /(\d+\s\w+) linear/;
is $1, '276 aa';
[download]

Thank you so much hippo it worked :)

use strict;
use warnings;
use Test::Simple tests => 3;
my $fname = \do {
    my $line = "BOGUS PPI3_SYNY3 276 aa contentar BCT 13-NOV-2019\n";
};

open my $FH, '<', $fname or die "Cannot open $fname for input";
my $content = <$FH>;
close $FH;

my $get_bogus = qr/ [A-Z0-9_]+ /x;
my $get_acid  = qr/ [0-9]+\s[a-z]+ /x;

my ( $bogus, $acids )
    = $content =~ / BOGUS \s+ ($get_bogus) \s+ ($get_acid) /x;

if (ok( ( defined($bogus)  and defined($acids) ), 'Match') ) {
    ok( $bogus eq "PPI3_SYNY3" , "extracted '$bogus'");
    ok( $acids eq '276 aa', "extracted '$acids'");
}
[download]

OUTPUT:

1..3
ok 1 - Match
ok 2 - extracted 'PPI3_SYNY3'
ok 3 - extracted '276 aa'
[download]