#!/usr/bin/perl
use warnings;
use strict;
use feature qw{ say };

my @content = (<DATA>);

my $no_of_seq = scalar(@content);

my @myArray;
for my $row (@content) {
    my @columns = split ' ', $row;
    push @myArray, \@columns;
}

say join "\t", $myArray[0][0], 'sum';
my $width = $#{ $myArray[0] };
for (my $row = 1; $row < $no_of_seq; $row++){
    print $myArray[$row][0], "\t";
    my $sum = 0;
    for my $col (@{ $myArray[$row] }[1 .. $width]) {
        $sum += $col;
    }
    say $sum;
}

__DATA__
GeneID    Tp1    Tp2    Tp3
ALA1    10    12    11
THR8    57    99    12
HUA4    100    177    199
ABA5    2    5    10
[download]

Update: But, to compute a sum of a row, you don't need the other rows, so you can process the file line by line, no need to store it into an array. List::Util already exports the sum sub, no need to compute it yourself.

#!/usr/bin/perl
use warnings;
use strict;
use feature qw{ say };

use List::Util qw{ sum };

<DATA>;  # ignore the first line;
say "GeneID\tSum";

while (<DATA>) {
    my @cols = split ' ';
    my $sum = sum(@cols[1 .. $#cols]);
    say join "\t", $cols[0], $sum;
}
[download]

And just in case you wanted to search by GeneID (which is very likely in a next step):

my %myArray; #my @myArray;
my $GeneID = shift @columns; $myArray{$GeneID} = \@columns; #push @myA
+rray, \@columns;

# and how to calculate sum of each row
for my $GeneID (sort keys %myArray){ # optionally sort to have a consi
+stent view
  my $sum = 0;
  for my $colItem (@{$myArray{$GeneID}}){
    $sum += $colItem;
  }
  print "sum for $GeneID: $sum\n";
}
[download]

bw, bliako

It seems from your post history that you are interested in bioinformatics, in case you are not aware BioPerl exists, and provides various solutions to common tasks, in addition to other things.

Update: Also Tutorials->Perl and Bioinformatics.

Hi marto i know about BioPerl but i don't want to use that i just want to do it the manual way the way i am doing it.

You will need to keep a count of the total per row, but you are not doing so yet. Further your code is trying to add a single value to an array which logically makes no sense. Also, each row contains the gene name as well as the data so you need to avoid trying to add a number to a string.

Using your loop structures then we might try this instead:

for($row = 0; $row < $no_of_seq; $row++){
        my $sum = 0;
        for($col = 1; $col < $no_of_seq; $col++){ 
            $sum += $myArray[$row][$col];
        }
        print "$myArray[$row][0] $sum\n";
}
[download]

But that's not very perlish. Let's improve the loops:

for my $row (@myArray) {
        my $sum = 0;
        for ($col = 1 .. $no_of_seq - 1) { 
            $sum += $row[$col];
        }
        print "$row[0] $sum\n";
}
[download]

This could be further cleaned if you work on a copy of @myArray which you could disrupt as you go. Putting this all together we arrive at the SSCCE:

#!/usr/bin/env perl 
use strict;
use warnings;

my @myArray;

while (<DATA>) {
    my @columns = split /\s+/, $_;
    push @myArray, \@columns;
}
my $title_row = shift @myArray;

for my $row (@myArray) {
    my $sum = 0;
    for my $col (1 .. $#$row) {
        $sum += $row->[$col];
    }
    print "$row->[0] $sum\n";
}

__DATA__
GeneID    Tp1    Tp2    Tp3        
ALA1    10    12    11        
THR8    57    99    12        
HUA4    100    177    199        
ABA5    2    5    10
[download]

Unfortunately your solution isn't printing anything to the terminal :(

Sure it does:

$ cat bio.pl 
#!/usr/bin/env perl 
use strict;
use warnings;

my @myArray;

while (<DATA>) {
    my @columns = split /\s+/, $_;
    push @myArray, \@columns;
}
my $title_row = shift @myArray;

for my $row (@myArray) {
    my $sum = 0;
    for my $col (1 .. $#$row) { 
        $sum += $row->[$col];
    }
    print "$row->[0] $sum\n";
}

__DATA__
GeneID    Tp1    Tp2    Tp3        
ALA1    10    12    11        
THR8    57    99    12        
HUA4    100    177    199        
ABA5    2    5    10
$ ./bio.pl 
ALA1 33
THR8 168
HUA4 476
ABA5 17
$ perl -v

This is perl 5, version 20, subversion 3 (v5.20.3) built for x86_64-li
+nux-thread-multi
(with 16 registered patches, see perl -V for more detail)

Copyright 1987-2015, Larry Wall

Perl may be copied only under the terms of either the Artistic License
+ or the
GNU General Public License, which may be found in the Perl 5 source ki
+t.

Complete documentation for Perl, including FAQ lists, should be found 
+on
this system using "man perl" or "perldoc perl".  If you have access to
+ the
Internet, point your browser at http://www.perl.org/, the Perl Home Pa
+ge.

$
[download]

G'day shabird,

"How can i achieve my desired result?"

You could try the sum0 function from the core List::Util module.

This code:

#!/usr/bin/env perl

use strict;
use warnings;

use List::Util 'sum0';

my (@all_data, @sum_data);

while (<DATA>) {
    next if $. == 1;
    push @all_data, [split];
}

print "All (original) data:\n";
print "@$_\n" for @all_data;

for (@all_data) {
    push @sum_data, [$_->[0], sum0 @$_[1 .. $#$_]];
}

print "\nSummary data:\n";
print "@$_\n" for @sum_data;

__DATA__
GeneID  Tp1 Tp2 Tp3
ALA1    10  12  11
THR8    57  99  12
HUA4    100 177 199
ABA5    2   5   10
[download]

Produces this output:

All (original) data:
ALA1 10 12 11
THR8 57 99 12
HUA4 100 177 199
ABA5 2 5 10

Summary data:
ALA1 33
THR8 168
HUA4 476
ABA5 17
[download]