I don't like your code to populate your hash, namely:

my ($key, $value) = split /\s/, $line;
next LINE if not $key;
$hash{$key} = $value;
chomp (%hash);
[download]

I would do it something like this:

use strict;
use warnings;
use Data::Dumper;
my %hash;
open my $fh, '<', 'hash.txt' or die "Can't open file $!";
while (my $line = <$fh>)
     {
     chomp $line;                  # remove trailing newline
     $line =~ s/^\s+//;            # optional: remove leading whitespa
+ce
     $line =~ s/\s+$//;            # optional: remove trailing whitesp
+ace
     next unless length($line);    # ignore blank lines
     next if $line =~ /^#/;        # optional: to allow comment lines
     # Format: key whitespace value (value can contain whitespace)
     my ($key, $value) = split ' ', $line, 2;
     defined($value) or die "error: no value for '$key'";
     $hash{$key} = $value;
     }
close $fh;
print Dumper(\%hash);
[download]

You might further want to consider what will happen if your key contains regex metachars (e.g. abc.xyz). Maybe this can't happen for your data ... but if it does, your regex may be incorrect (could use /\Q$key\E/ to escape metachars, if required by your data).

Re safely editing a file in place, see:

• Perl Best Practices book: is this one a best practice or a dodgy practice?
• Re-runnably editing a file in place

... the doco for chomp does not mention applying it to a hash ...

chomp sez: If VARIABLE is a hash, it chomps the hash's values, but not its keys...

---

Give a man a fish:   <%-(-(-(-<

Copy them to new variables before using them.

edit

Not sure why you even need two nested regexes here... One s/// should be sufficient.

Thanks Rolf, I am not sure this is what you meant but I changed it to:

 while (<FH>)
          {
          if (/(\S+):(\S+).*\n/)
               {
               $var1 = "$1";
               $var2 = "$2";
               s/$var1/$hash{$var1}_$var/g;
               }
           }
[download]

and now I get a different Use of uninitialized value error, which seems better?:

"Use of uninitialized value within %hash in concatenation (.) or string at test_perl.pl line 41"

I don't understand your comment about nested regexes, could you elaborate? Thanks in advance for any help

Some other thoughts on the OPed code.

my ($key, $value) = split /\s/, $line;
next LINE if not $key;

split returns its input string ($line in this case) if it cannot split according to the given pattern, so  $key will almost always have a true value no matter what happens. Better to use
    my ($k, $v) = split /\s/, $line;
    next LINE if not defined $v;
I use defined to avoid false negatives from  '0' and  '' (the empty string), both of which evaluate as boolean false. I also use the variable names  $k $v because I don't like using variaable names that are the same as Perl built-in functions, etc.

$hash{$key} = $value;

The hash  %hash is presumably a package global. Better to use a pre-declared my lexical. (Better in general to avoid globals.)

chomp (%hash);

The chomp is done on all the values of the hash on every iteration through the while-loop. This does no harm, but needlessly burns cycles. chomp can be done just once on the hash after it is populated, i.e., after the while-loop.

Update: This code doesn't seem to really do anything:

@file_array =<*.txt> or die $!; 
foreach $file (@file_array)
     {
     open FH, "$file", or die $!;
     while (<FH>)
          {
          if (/(\S+):(\S+).*\n/)
               {
               s/$1/$hash{'$1'}_$2/g;
               }
          }
     close FH;
      }
[download]

Further Update: The process of "editing a file" (that has not been read into a tied array) on a line-by-line basis generally goes something like this (every step is assumed to be checked for success, i.e., it produces no error code):

1. open file to be edited (input file) in read mode ('<').
2. Generate temporary name of output file (usually based on input file name) and open for write ('>')
3. Until all lines are read from input file, read input file line-by-line, alter line as appropriate, write line to output file.
4. Close input file. Close output file.
5. Do whatever is necessary to be absolutely sure the newly-written output file is intact.
6. Change name of input file to some backup name, e.g., 'input.txt.bak'.
7. If the input file name change produces no errors, rename output file to original name of input file. If the output file rename is successful, the "backup" input file may be deleted; often, this file is kept in existence "just in case."

Anomalous, you're right. As I wrote in my original post, I have never actually used s/foo/bar other than in a one liner. I was looking for a way to find and replace strings in a file without writing to a new output file and when the replacement strings are not the same length as the sub-strings that are replaced. Clearly I am not doing this the correct way, and if there is a correct way, I haven't been able to find/understand it yet. What I want is to open a file and if a line is:

'nc7-52:p39|read1|1|19|296|0.0642'

and change it to:

C_fraterna_nc7-52

using a hash where $hash{nc7-52}=C_fraterna_nc7-52

Update: From this example it looks like it would be easy to print to output, but some lines in the file will not be modified and I still want to preserve them.

sorry, this thread may be a bit out of control since I had too many problems to begin with

From this example it looks like it would be easy to print to output ...

As a first step, create a small test input file and just print the altered and unaltered lines to standard output, e.g.,
    print $my_new_line_what_is_just_the_way_i_want_it;
When this limited, test output looks ok, start to think about the process of opening a new file and writing to that file instead of STDOUT. When that looks ok, start thinking about all the input/output file verification and renaming that has to happen. (I'm sure there are modules to facilitate the "edit in place" process, but I don't know what they are off-hand.)

---

Give a man a fish:   <%-(-(-(-<

Please see Update and Further Update to Re: In place search and replace with a hash. (Unfortunately, we may be playing "update tag.")

---

Give a man a fish:   <%-(-(-(-<

I think I understand your editing a file instructions, and if so I was really over-complicating things trying to do an "in place" replacement. Now I am trying something like this:

 
open FH, "<infile.txt" or die $!;
open OUT, ">outfile.txt";
while (<FH>)
          {
          if (/(\S+):(\S+).*\n/)
               {
               $var1 = "$1";
               $var2 = "$2";
               print OUT "$var1_$var2\n"
               }
            elsif (/(.*)\n/)
                {
                print OUT "$1\n";
               }
            }
     close FH;
[download]

This does what I want in terms of preserving the input files non matching lines, but I am still getting a "use of uninitialized value" error, one for every line in the input file:

Use of uninitialized value $var1_ in concatenation (.) or string at test_perl.pl line 42

print OUT "$var1_$var2\n"


The  '_' (underscore) character is a valid identifier, i.e., variable name, symbol. Therefore, the two variables you're using are  $var1_ (note trailing _), which is not defined, and  $var2, which is. Had you been using strictures as well as warnings, Perl would not have allowed this little oversight (see strict and warnings). The proper way to write this statement (if you really need the _) is
    print OUT "${var1}_$var2\n";
(Note that I've added a ; at the end; the absence of this statement terminator caused no syntactic problem in the given code, but would have eventually — trust me.)

open FH, "<infile.txt" or die $!;
open OUT, ">outfile.txt";


Update: You seem to be back-sliding. In contrast to your OPed code, this code uses global filehandles, two-parameter open, and does not check the status of the output file open. Tsk, tsk! IMHO, the OPed code used better practices.

---

Give a man a fish:   <%-(-(-(-<

if (/(\S+):(\S+).*\n/)
     {
     $var1 = "$1";
     $var2 = "$2";
     print OUT "$var1_$var2\n"
     }
  elsif (/(.*)\n/)
      {
      print OUT "$1\n";
      }
     }
[download]

Ok, once you get that working (i.e., fix  $var1_ problem), try reducing the big if-statement to a single  s/// substitution (untested):
    s{ (\S) : (\S) }{${1}_$2}xmsg;
(which just replaces every : with an _), followed by a print of the (possibly altered) line (held in  $_ in this code) to the output filehandle.

Update: This reply may have been superseded by your intervening post, but what the heck...

---

Give a man a fish:   <%-(-(-(-<

Did you test it?

I can't at the moment°, but imho the first step on RHS is string like var interpolation. There is no eval flag set.

Cheers Rolf

_{(addicted to the Perl Programming Language and ☆☆☆☆ :)}

°) mobile in a disco, ain't that I'll? ;)

c:\@Work\Perl\monks>perl -wMstrict -le
"my %hash = ('$1' => 'oops',  'abc' => 'ok');
 ;;
 'abc' =~ m{ (abc) }xms;
 print qq{captured '$1'};
 ;;
 print $hash{'$1'};
"
captured 'abc'
oops
[download]

---

Give a man a fish:   <%-(-(-(-<

You're so addicted to Perl you can't forget it even in a disco :)

It works with strings too :)

use 5.020;
use warnings;

my %h = ( foo => 1, bar => 2 );

$_ = 'foobar';
s/(foo)/$h{'$1'}/;
say $_;

$_ = 'foobar';
s/(foo)/$h{$1}/;
say $_;

my $foo = 'foo';
say "$h{'$foo'}bar";
[download]

output:

Use of uninitialized value $h{"$1"} in substitution iterator at extr.p
+l line 7.
bar
1bar
Use of uninitialized value $h{"$foo"} in concatenation (.) or string a
+t extr.pl line 15.
bar
[download]

Oops, I meant to respond "thanks for catching that" Anonymous Monk but I got the usernames mixed up. Well thanks!

Thanks for catching that LanX