G'day saw55,

Welcome to the Monastery.

I see the reason for your problem has been explained by ++jcb.

Instead of calling exit(0) as you currently do, consider passing a flag that instructs &timedDialog to either destroy the dialogue or exit the application.

Here's a fully functional, albeit extremely barebones, example of what I mean.

#!/usr/bin/env perl

use strict;
use warnings;

use Tk;

{
    my $mw = MainWindow::->new();

    $mw->Button(
        -text => 'Transient message',
        -command => sub { out_msg(\$mw, 'Message ...', 2_000) },
    )->pack();

    $mw->Button(
        -text => 'No backup',
        -command => sub { out_msg(\$mw, 'Exiting ...', 2_000, 1) },
    )->pack();
}

sub out_msg {
    my ($mw_ref, $msg, $delay, $exit) = @_;

    my $tl = $$mw_ref->Toplevel();
    $tl->Label(-textvariable => \$msg)->pack();
    my $handle_msg = $exit
                   ? sub { exit }
                   : sub { $tl->destroy };
    $tl->after($delay, $handle_msg);
}

MainLoop;
[download]

Note that the flag is only needed for those callbacks where you want to exit: you may only need to make minimal changes if you adopt this technique.

Thanks you so much, and thanks to jcb as well. As I am sure you you can tell, I am new to Tk, but this gives me something to work with. I knew there were standard popups available--I use them elsewhere in the program--but I think I couldn't figure out how to close them programatically.

"Thanks you so much"

You are very welcome.

"I knew there were standard popups ... but I think I couldn't figure out how to close them programatically."

Take a look at the invoke() method of Tk::Button. You could give the option to close manually via a button or, if that option isn't taken, close programmatically after the specified delay.

— Ken

#!/usr/bin/perl

use strict; # https://perlmonks.org/?node_id=11114965
use warnings;
use Tk;

my $mw = MainWindow -> new;
$mw->geometry( '+600+400' );
my $timedDialogTitle = '';
my $timedDialogText = '';
my $svBtn = undef; #Option window SAVE button.

&setupGUI;
#$mw->deiconify();
#$mw->raise();
MainLoop;
#exit(0);

################################################
################################################

sub setupGUI{
    $timedDialogTitle = "STARTING BACKUP";
    $timedDialogText = "Backing up files...";

    $svBtn = $mw->Button( -text => "SAVE",
      -command => sub {&checkDays;
#     exit(0);
      });

    $svBtn->grid(-row => 9, -column => 2, -sticky => 'e');

    $mw->bind('<KeyPress-Return>' => sub {checkDays();
#     exit(0);
      });

#    $mw-> withdraw();

}
#####################################

sub checkDays 
  {
  timedDialog("Exiting",
    "O.K., no backup will be made, then....Exiting",
    2_000);

  }

#####################################

sub timedDialog
  {
  print ("in timedDialog\n");
# my $subwindow = MainWindow->new;
  my $subwindow = $mw->Toplevel;
  $subwindow->geometry("490x150+400+400");
  $subwindow->title($_[0]);
  my $label = $subwindow->Label(-text => $_[1]);
  $label->pack;
  $subwindow->after($_[2], sub {$subwindow->destroy;});
  print ("after timedDialog\n");
  }

#####################################
[download]

Hi, I am not a Tk programmer, but ... exit exits :-) If you want to return from a sub, return :-)

(And commenting out the exit statement makes your script work because you don't need to use an explicit return statement to return from a sub, if you are not returning anything.)

Hope this helps!

G'day 1nickt,

The link you posted labeled "exit" is to a Google search (http://www.google.com/search?q=exit%20site%3Aperldoc.perl.org). The first item returned from that search is to perldoc (https://perldoc.perl.org/functions/exit.html). I couldn't see anything else pertinent, so I'm wondering why the intermediary Google step. Anyway, the point is somewhat moot as that's the wrong "exit".

"I am not a Tk programmer ..."

In my experience, even amongst Tk programmers, it's a little known fact that Tk exports, by default, its own exit: Tk::exit.

Knowing that doesn't help the OP but I thought it was worth mentioning.

— Ken

Thanks Ken, I'll update the link. Not sure how that happened.

Update: I fixed the links by changing from [perldoc:// to [doc://. I wonder if the behaviour of the former syntax is new, broken, or something I just imagined was different. The links as I originally posted definitely went to a Goog search. Maybe a topic for PM Discussion...


The way forward always starts with a minimal test.

As I understand, the two exit procedures only matter if you fork. Calling Tk's exit from a forked child causes the parent to also exit, while calling CORE::exit causes only that forked child to exit.

Thanks for the reply. I know exit causes the program to exit, but I believe the call to the subroutine preceding the exit statement should cause the message window to display before the program exits. I know sub timedDialog executes because I inserted a print statement in it and it does indeed print but the message window never displays; and I put a sleep statement between the sub call and exit in hope of allowing time for the message to display but no go.

I just noticed I called timedDialog both in sub checkDays and in sub setupGUI I fixed this and still no message shows

Fixed code follows

#!/usr/bin/perl
######################################################################
+##
use strict;
use warnings;
use Tk;

my $mw = MainWindow -> new;
my $timedDialogTitle = '';
my $timedDialogText = '';
my $svBtn = undef; #Option window SAVE button.

&setupGUI;
$mw->deiconify();
$mw->raise(); 
MainLoop;
exit(0);

################################################
################################################

sub setupGUI{

    $svBtn = $mw->Button( -text => "SAVE", -command => sub {&checkDays
+; exit(0);});

    $svBtn->grid(-row => 9, -column => 2, -sticky => 'e');

    $mw->bind('<KeyPress-Return>' => sub {&checkDays; exit(0);});

    $mw-> withdraw();

}
#####################################

sub checkDays {
                &timedDialog("Exiting", "O.K., no backup will be made,
+ then....Exiting", 25_000);
                sleep 15;
    }
#####################################

sub timedDialog
{
print ("in timedDialog\n");
my $subwindow = MainWindow->new;
    $subwindow->geometry("490x150+400+400"); 
    $subwindow->title($_[0]);
my $label = $subwindow->Label(-text => $_[1]);
$label->pack;
$subwindow->after($_[2], sub {$subwindow->destroy;});
}
#####################################
[download]

All UI activity in Tk occurs in the Tk event loop. You are exiting the program from an event handler before returning control to the event loop. Try replacing that handler with sub {&checkDays; $mw->after(5000, sub {exit(0)});} and see Tk::after for more details.