If you want to fill a node regardless of whether it contains any text, don't use its text contents - as there can be none. Clean the node instead and add the new text:

#! /usr/bin/perl
use strict;
use feature qw{ say };
use warnings;

use XML::LibXML;

my $xml = '<header>
   <id x_id="1">
      <a></a>
      <b></b>
      <c>NA</c>
   </id>
</header>';

print "Please specify node c content: ";
chomp( my $new_text = <STDIN> );

my $dom = 'XML::LibXML'->load_xml(string => $xml);
for my $node($dom->findnodes('(/header/id/b | /header/id/c)')) {
    $node->removeChildNodes;
    $node->appendText($new_text);
}
print $dom;
[download]

Or, try XML::XSH2:

open file.xml ;
for (/header/id/b|/header/id/c) set text() "YOUR TEXT HERE" ;
save :b ;
[download]

Hi, it was a typo in my original post. I tried your code and it shows XML::LibXML::Document=SCALAR(0x6e7fd0)

I edited it to load file from my cwd. It seems still interrupting empty node: Code:

#! /usr/bin/perl
use strict;
use feature qw{ say };
use warnings;

use XML::LibXML;

print "Please specify node c content: ";
chomp( my $new_text = <STDIN> );
my $file = 'xx.xml';
my $dom = 'XML::LibXML'->load_xml(location => $file);
for my $node($dom->findnodes('(/header/id/c)')) {
    $node->removeChildNodes;
    $node->appendText($new_text);
}
#print $dom;
open (my $Output, "> $file") or die "Could not write $file";
print $Output $dom->toString();
close ($Output) or die "Could not close generated $file ";
[download]

Output:

<?xml version="1.0"?>
<header>
   <id x_id="1">
      <a/>
      <b/>
      <c>as</c>
   </id>
</header>
[download]

Expecting output:

<?xml version="1.0"?>
<header>
   <id x_id="1">
      <a></a>
      <b></c>
      <c>something</c>
   </id>
</header>
[download]

As posted your script returns:

Global symbol "$node_c" requires explicit package name (did you forget
+ to declare "my $node_c"?) at derp.pl line 13.
Execution of derp.pl aborted due to compilation errors.
[download]

Where possible please copy/paste rather than retype code. I've never used XML::LibXML (at least not that I can remember at this time of day), but believe your example should look something like this:

use strict;
use warnings;
use XML::LibXML;

print "Please specify node c content\n";
my $node_c = <STDIN>;
chomp $node_c;

my $template = "xx.xml";
my $parser = XML::LibXML->new();
my $doc = $parser->parse_file($template);
my($object0) = $doc->findnodes("/header/id/c/text()");
$object0->setData( $node_c );
print $doc;
[download]

Output:

Please specify node c content
derp
<?xml version="1.0"?>
<header>
   <id x_id="1">
      <a/>
      <b/>
      <c>derp</c>
   </id>
</header>
[download]

Update: Correct use of XML::LibXML here

Or using Mojo::DOM:

#!/usr/bin/perl
use strict;
use warnings;
use feature 'say';
use Mojo::DOM;

my $xml = '<header>
   <id x_id="1">
      <a></a>
      <b></b>
      <c>NA</c>
   </id>
</header>';

my $dom = Mojo::DOM->new->xml(1)->parse( $xml );

say 'Current value of c: ' . $dom->at('id > c')->text;
say 'Please specify node c content: ';
chomp( my $node_c = <STDIN> );
$dom->at('id > c')->content( $node_c );
say $dom->content;
[download]

Output:

Current value of c: NA
Please specify node c content: 
derp
<header>
   <id x_id="1">
      <a />
      <b />
      <c>derp</c>
   </id>
</header>
[download]

Hi, I have not try on your code but from the output you posted, it seems remove and from the original file. Is there anyway to retain empty node a and b?

That is valid XML for a node with no content or attributes.

#!/usr/bin/perl
use strict;
use warnings;
use feature 'say';
use Mojo::DOM;

my $xml = '<header>
   <id x_id="1">
      <a></a>
      <b></b>
      <c>NA</c>
   </id>
</header>';

my $dom = Mojo::DOM->new->xml(1)->parse( $xml );

say 'Current value of c: ' . $dom->at('id > c')->text;
say 'Please specify node c content: ';
chomp( my $node_c = <STDIN> );
$dom->at('id > c')->content( $node_c );
say $dom->content;
say 'add content to nodes a & b';
$dom->at('id > b')->content( 'Foo' );
$dom->at('id > a')->content( 'Bar' );
say $dom->content;
[download]

Output:

Current value of c: NA
Please specify node c content: 
derp
<header>
   <id x_id="1">
      <a />
      <b />
      <c>derp</c>
   </id>
</header>
add content to nodes a & b
<header>
   <id x_id="1">
      <a>Bar</a>
      <b>Foo</b>
      <c>derp</c>
   </id>
</header>
[download]