G'day DcmbrAgnt,

You really haven't shown enough code to be certain; however, I suspect your problem may lie with this:

sub { $midi_indev = $midi_outdev; ...}
[download]

The $midi_indev is a package (global) variable. You don't actually use it in the sub where it's assigned a value. As you don't show any code where $midi_indev is also used, I won't speculate further.

You should be using the strict and warnings pragmata: see "perlintro: Safety net".

What you probably need to do is create a reference to $midi_outdev before constructing the Tk::BrowseEntry widget. Then use that reference something like this:

my $midi_outdev_ref = \$midi_outdev;
...
    -variable => $midi_outdev_ref,
    ...
    sub { my $midi_indev = $$midi_outdev_ref; ... },
    ...
[download]

Here's a very bare-bones example:

#!/usr/bin/env perl

use strict;
use warnings;

use Tk;
use Tk::BrowseEntry;

my @choices = 'A' .. 'Z';
my $picked = $choices[0];
my $picked_ref = \$picked;

my $mw = MainWindow::->new();

$mw->BrowseEntry(
    -variable => $picked_ref,
    -choices => \@choices,
)->pack();

$mw->Button(
    -text => 'Print Choice',
    -command => sub {
        print "Choice: $$picked_ref\n";
    },
)->pack();

MainLoop();
[download]

This code is fully functional. It always shows 'A' as the initial selection; it always prints the last selected value whenever the "Print Choice" button is used.

"... ALSA MIDI ports, which are being scanned with MIDI::ALSA and put into an array long before the BrowseEntry widget ever gets configured or displayed."

There may also be something wrong about that assertion. Do you know for certain or is that an assumption? Without seeing your code, I can't tell.

If the above suggestions don't help, please create an SSCCE that reproduces your problem. Do keep it short: unless it's relevant, omit anything to do with colours, fonts, justification, and so on.

You might also like to take a look at the Widget Demo. In case you don't know, just type widget on the command line. I can see two examples using Tk::BrowseEntry under Tix Widgets (items 2 & 3).

Every time I run the following program, the BrowseEntry entry comes up blank. I see no alternating behavior. The only way I can get the entry to show initial content is to uncomment the
    $midi_outdev = 'INITIAL CONTENT';
statement (update: and then I always get the same initial content :). Can you post a Short, Self-Contained, Correct Example that shows the behavior you're seeing?

c:\@Work\Perl\monks>perl
use strict;
use warnings;

use Tk;
use Tk::BrowseEntry;

my $midiCtrls = tkinit;

my @midi_outdevs = (
  'the rain in spain',
  'the cat in the hat',
  'how now brown cow',
  'foo bar baz',
  'now is the time',
  );

my $midi_outdev;
# $midi_outdev = 'INITIAL CONTENT';

my $midi_indev;

my $dropdwnMidiPort = $midiCtrls->BrowseEntry(
    -choices          => \@midi_outdevs,
    -state            => 'readonly',
    -justify          => 'right',
    -variable         => \$midi_outdev,
    -browsecmd        => sub { $midi_indev = $midi_outdev;
                   MidiConSetup('out');
                   MidiConSetup('in'); },
    -font             => 'Helvetica -12 bold',
    -disabledforeground => 'black')->grid(
    -row              => 0,
    -column           => 0);
$dropdwnMidiPort->Subwidget('slistbox')->configure(
    -selectbackground => 'IndianRed4',
    -selectforeground => 'white');

MainLoop;

exit;

sub MidiConSetup { print qq{'$_[0]' '$midi_indev' \n}; }

__END__
'out' 'how now brown cow'
'in' 'how now brown cow'
'out' 'now is the time'
'in' 'now is the time'
'out' 'the rain in spain'
'in' 'the rain in spain'
[download]