You may use the "branch reset" pattern:

#!/usr/bin/perl

use strict;
use warnings;
use feature 'say';

for (qw(/key/123 /123-456)) {
    my ($id) = m!(?|/key/(\d+)|/(\d+)-\d+)!;
    say $id;
}
__DATA__
123
123
[download]

EDIT: Added the missing leading slash in the second branch.

The branch reset operator is a regex pattern extension added with Perl version 5.10. For those of you still clomping around in the pre-5.10 Stone Age, here's an old-school alternative:

c:\@Work\Perl\monks>perl -wMstrict -le
"for my $s (qw(/key/42  /key/  /24-99  /24-  /24  /key/42-99)) {
   my $parsed =
   my ($id) =
   grep defined,
   $s =~ m{ \A (?: /key/ (\d+) | / (\d+) - \d+) \z }xms;
   ;;
   print qq{'$s' -> }, $parsed ? qq{'$id'} : 'no id';
   }
"
'/key/42' -> '42'
'/key/' -> no id
'/24-99' -> '24'
'/24-' -> no id
'/24' -> no id
'/key/42-99' -> no id
[download]

(Of course, this still works post-5.10!)

---

Give a man a fish:  <%-{-{-{-<

You may use the "branch reset" pattern:

Thanks! It works exactly as I wanted to...

my ($id) = grep defined, (m!/key/(\d+)|/(\d+)-\d+!);
[download]

that's IMHO the shortest and most intuitive

 
  DB<35> $_='a'

  DB<36> ;  /(a)/ or /(b)/; $x= $1

  DB<37> p $x
a
  DB<38> $_='b'

  DB<39> ;  /(a)/ or /(b)/; $x= $1

  DB<40> p $x
b
  DB<41>
[download]

I'm aware you wanted the list assignment approach, but it's longer because you'd need to repeat ($x) = for each term and I prefer DRY idioms.

It's also ambiguous if all matches fail:

c:\@Work\Perl\monks>perl -wMstrict -le
"for (qw(a X b)) {
   /(a)/ or /(b)/;
   my $id = $1;
   print qq{'$_' -> '$id'};
   }
"
'a' -> 'a'
'X' -> 'a'
'b' -> 'b'
[download]

Update 1: Something like
    my $id = $1 // $2 if m!/key/(\d+)|/(\d+)-\d+!;
(if you avoid the problem of the conditionally declared lexical!) does not suffer this:

c:\@Work\Perl\monks>perl -wMstrict -le
"for (qw(a X b)) {
   /(a)|(b)/ or next;
   my $id = $1 // $2;
   print qq{'$_' -> '$id'};
   }
"
'a' -> 'a'
'b' -> 'b'
[download]

Update 2: Slight wording change to first sentence.

---

Give a man a fish:  <%-{-{-{-<

good point, $1 sticks to the last successful match

so always check before accessing it

for (qw(a X b)) {
    my $id = $1
      if /(a)/ or /(b)/;

   print qq{'$_' -> '$id'\n};

}
[download]

C:/Perl_524/bin\perl.exe -w d:/exp/pm_or_regex.pl 
Use of uninitialized value $id in concatenation (.) or string at d:/ex
+p/pm_or_regex.pl line 5.
'a' -> 'a'
'X' -> ''
'b' -> 'b'
[download]

I kept the warning in intentionally.

Cheers Rolf
_{(addicted to the Perl Programming Language :)
Wikisyntax for the Monastery}