Partly in answer to choroba's challenge, here's an approach that works with forward/backslashes, escape sequences and capture variables in replacement strings. Whether it will answer your needs is another question. A fixup step for forward slashes is necessary. Works under Perl versions 5.8.9 and 5.30.3.

Win8 Strawberry 5.8.9.5 (32)  Thu 11/26/2020  4:08:05
C:\@Work\Perl\monks
>perl
use strict;
use warnings;

my $pattern     = '(\\\\tEs/Ti//N\x67\\\)';
my $replacement = '\\\Fr/es//h\\\\ \U$1';
my $flags       = 'i';

# $got_g is true if /g modifier present in flags.
# ($flags, my $got_g) = sanitize_flags_detect_g($flags);

fixup_forward_slashes($pattern, $replacement);

my $value = 'My \Tes/ti//ng\ Text';

print "replacement '$replacement' \n";

my $eval_string = "\$value =~ s/$pattern/$replacement/$flags";
print "eval_string '$eval_string' \n";

eval $eval_string;
print "eval err '$@' \n";
print "output '$value' \n";

sub fixup_forward_slashes { s{/}'\/'g for @_; }

^Z
replacement '\\Fr\/es\/\/h\\ \U$1'
eval_string '$value =~ s/(\\tEs\/Ti\/\/N\x67\\)/\\Fr\/es\/\/h\\ \U$1/i
+'
eval err ''
output 'My \Fr/es//h\ \TES/TI//NG\ Text'
[download]

OK, now try to include a slash into the pattern or replacement.

we already need to trust the people who write the configuration files that will contain the values used in the eval.

Beware Hanlon's Razor. Are you trusting them to be competent or just benign? In your shoes I would be untainting their input very conservatively.

It's working, and crucially supports back-references

That's interesting as I cannot get this to support back-references...this is very similar to my initial attempt. So I have attempted to replicate it:

use strict;

my $pattern     = '(testing)';
my $replacement = 'New \1';
my $flags    = 'i';

my $value    = 'My Testing Text';

$replacement =~ s/\\/\\\\/g;
eval "\$value =~ s/$pattern/$replacement/$flags";

print "$value\n";
[download]

  My New \1 Text
[download]

The OPed sort of problem is tricky, but for this specific iteration:

Win8 Strawberry 5.8.9.5 (32)  Wed 11/25/2020 22:12:13
C:\@Work\Perl\monks
>perl
use strict;
use warnings;

my $pattern     = '(testing)';
my $replacement = 'New \U$1';
my $flags       = 'i';

my $value = 'My Testing Text';

### $replacement =~ s/\\/\\\\/g;
print "replacement '$replacement' \n";

eval "\$value =~ s/$pattern/$replacement/$flags";

print "$value\n";
^Z
replacement 'New \U$1'
My New TESTING Text
[download]

(An escaped backreference \1 is not kosher in a replacement string anyway; it should be in $1 form.)

Update: Here's a version of the example code that better illustrates the process of building the evaluation string:

Win8 Strawberry 5.8.9.5 (32)  Wed 11/25/2020 22:45:44
C:\@Work\Perl\monks
>perl
use strict;
use warnings;

my $pattern     = '(testing)';
my $replacement = 'New \U$1';
my $flags       = 'i';

my $value = 'My Testing Text';

print "replacement '$replacement' \n";

my $eval_string = "\$value =~ s/$pattern/$replacement/$flags";
print "eval_string '$eval_string' \n";

eval $eval_string;

print "$value\n";
^Z
replacement 'New \U$1'
eval_string '$value =~ s/(testing)/New \U$1/i'
My New TESTING Text
[download]

---

Give a man a fish:  <%-{-{-{-<