> $method ... can also be an overloaded object though,

Is it really possible to overload the arrow operator -> for method calls from the RHS???

I only see dereferencing listed ${} @{} %{} &{} *{}

 with_assign      => '+ - * / % ** << >> x .',
assign           => '+= -= *= /= %= **= <<= >>= x= .=',
num_comparison   => '< <= > >= == !=',
'3way_comparison'=> '<=> cmp',
str_comparison   => 'lt le gt ge eq ne',
binary           => '& &= | |= ^ ^= &. &.= |. |.= ^. ^.=',
unary            => 'neg ! ~ ~.',
mutators         => '++ --',
func             => 'atan2 cos sin exp abs log sqrt int',
conversion       => 'bool "" 0+ qr',
iterators        => '<>',
filetest         => '-X',
dereferencing    => '${} @{} %{} &{} *{}',
matching         => '~~',
special          => 'nomethod fallback ='
[download]

As I said, the string overload is used.

use strict;
use warnings;
use feature 'say';

BEGIN {
    package Local::Farm;
    sub new {
        my ( $class ) = ( shift );
        bless {}, $class;
    }
    sub cow_say {
        say "Moo";
    }
    sub sheep_say {
        say "Baa";
    }
    sub horse_say {
        say "Neigh";
    }
};

BEGIN {
    package Local::Random::String;
    use overload q[""] => 'to_string', fallback => 1;
    sub new {
        my ( $class, @options ) = ( shift, @_ );
        bless \@options, $class;
    }
    sub to_string {
        my ( $self ) = ( shift );
        my $ix = rand @$self;
        $self->[$ix];
    }
};

my $object = 'Local::Farm'->new();
my $method = 'Local::Random::String'->new( qw/ cow_say sheep_say / );

$object->$method for 1 .. 10;
[download]

toby döt ink

Thanks for the code! :)

OK now I understand what you intended to say, but IMHO you are over-complicating things.

The rule is

• If $method is not a coderef, its string-value is used for a method lookup!

> As I said, the string overload is used.

No, if you bless a coderef, it'll still ignore the string-value. No matter if it was overloaded or not.

use strict;
use warnings;
use feature 'say';


BEGIN {
    package Local::Farm;
    sub new {
        my ( $class ) = ( shift );
        bless {}, $class;
    }
    sub cow_say {
        say "Moo";
    }
    sub sheep_say {
        say "Baa";
    }
    sub horse_say {
        say "Neigh";
    }
};

BEGIN {
    package Local::Random::String;
    use overload q[""] => 'to_string', fallback => 1;
    use Data::Dump qw/pp dd/;
    my @animal_say;

    sub still_a_function {
        say "still_a_function(". pp(\@_).")";
    }

    sub new {
        my ( $class, @options ) = ( shift, @_ );

        # @animal_say = @options;
        # return bless [], $class;

        return bless \&still_a_function, $class;
    }

    sub to_string {
        my ( $self ) = ( shift );
        my $ix = rand @animal_say;
        $animal_say[$ix];
    }

}
    ;

my $object = 'Local::Farm'->new();
my $method = 'Local::Random::String'->new( qw/ cow_say sheep_say / );




$object->$method for 1 .. 10;
[download]

-*- mode: compilation; default-directory: "d:/tmp/pm/" -*-
Compilation started at Thu Dec 10 11:17:21

C:/Perl_524/bin\perl.exe -w d:/tmp/pm/overload_string.pl 
still_a_function([bless({}, "Local::Farm")])
still_a_function([bless({}, "Local::Farm")])
still_a_function([bless({}, "Local::Farm")])
still_a_function([bless({}, "Local::Farm")])
still_a_function([bless({}, "Local::Farm")])
still_a_function([bless({}, "Local::Farm")])
still_a_function([bless({}, "Local::Farm")])
still_a_function([bless({}, "Local::Farm")])
still_a_function([bless({}, "Local::Farm")])
still_a_function([bless({}, "Local::Farm")])

Compilation finished at Thu Dec 10 11:17:22
[download]

Cheers Rolf
_{(addicted to the Perl Programming Language :)
Wikisyntax for the Monastery}

coderefified

Did this word exist before Dec 09, 2020 at 17:58 CET? Anyway, now it does.

Codified already has an established meaning which differs from what I meant.

toby döt ink