#!/usr/bin/perl
use warnings;
use strict;
use feature qw{ say };

use Text::CSV_XS;
use XML::LibXML;

my %name;
my $csv = 'Text::CSV_XS'->new({allow_whitespace => 1,
                               auto_diag        => 1,
                               binary           => 1});
open my $in, '<:encoding(UTF-8)', 'test.csv' or die $!;
$csv->header($in);
while (my $row = $csv->getline($in)) {
    $name{$row->[0]}{$row->[1]} = $row->[2];
}

my $dom = 'XML::LibXML'->load_xml(location => 'test.osm');
for my $node ($dom->findnodes('/osm/node')) {
    my $tag = $node->findnodes('tag[@k="name"]')->[0];
    if (my $name = $name{ $node->{lat} }{ $node->{lon} }) {
        $tag->{v} = $name;
    } else {
        warn "No name found for $tag->{v}: @$node{qw{ lat lon }}\n";
    }
}
$dom->toFile('new.osm');
[download]

Or, you can load the XML into a DOM, then read the CSV line by line, searching the DOM for the corresponding node and renaming it:

#!/usr/bin/perl
use warnings;
use strict;

use feature qw{ say };

use Text::CSV_XS;
use XML::LibXML;

my $dom = 'XML::LibXML'->load_xml(location => 'test.osm');

my $csv = 'Text::CSV_XS'->new({allow_whitespace => 1,
                               auto_diag        => 1,
                               binary           => 1});
open my $in, '<:encoding(UTF-8)', 'test.csv' or die $!;
$csv->header($in);

my $xpath_template = '/osm/node[@lat="%"][@lon="%"]';
while (my $row = $csv->getline($in)) {
    my $i = 0;
    my $xpath = $xpath_template =~ s/%/$row->[$i++]/gr;
    my $node = $dom->findnodes($xpath)->[0];
    if ($node) {
        my $tag = $node->findnodes('tag[@k="name"]')->[0];
        $tag->{v} = $row->[2];
    } else {
        warn "@$row missing in XML\n";
    }
}
$dom->toFile('new.osm');
[download]

Thank you very much. I did apply the code and it is working as expected.

What if there are some tag values which are in csv file and that needs to be added as new nodes in xml file with the maximum node id assigned. For e.g.-

"latitude";"longitude";"name";"id"
59.58464;8.56069;A13_PRA_KEI;-1643794
59.58464;8.56069;A13_RAT_KEI;-1643795
59.59465;8.57070;A14_PQR_KEI;-1643796
[download]

The first 2 rows have same lat and long value but the 2nd row value needs to be added in xml file as it has maximum node id value. Thank you.

When you build the hash, you can store both values (name and id) and each time compare to the existing id (a hash of hashes). If the new id isn't larger then just discard that row. You can then delete items from the hash as you go through the XML and add any left in the hash at the end.

---

🦛

Do you need to deal with fuzzy matching for the location points (accept match if points are with 100m for example)?

I don't know much about fuzzy matching but the idea was to just update the XML values with the CSV values by taking the lat and long as keys. Thank you for your support.

BTW, Getopt::Long should be enough. See also.

Other monks have given you help towards a solution, but I noticed a misunderstanding that will not help you: you do not have two primary keys, you have one primary key that happens to be a 2-tuple of (lat, lon) values. While you will have to match it piecewise, it is conceptually a single datum.

In the context of database like storage they are indeed two primary keys even though they represent one point. That single point may be associated with multiple entries in the "database" even if it is a single point (assuming of course it represents a point on a two dimensional substantially unfolded surface).

Optimising for fewest key strokes only makes sense transmitting to Pluto or beyond

They could both be keys but I don't see how they could both be primary unless combined into a single primary key as jcb suggested. Do you happen to use or know of a database that supports multiple primary keys on the same table?

---

🦛

Thank you for the Information. Since I am new to Perl so I don't know whether the tuple datatype can be used but anyways thank you.

There is no explicit tuple data type in Perl; you will need to either track both pieces in separate variables or use an array, but note that there are no builtin operators for comparing arrays elementwise: == on arrays compares their lengths (because it imposes scalar context on its operands) and == on array references checks for object identity (true if both references refer to the same object).

However, while the 2-tuple nature of your primary key will not be directly reflected in your program, properly understanding it will help you to maintain clear thinking and accurate reasoning about your code.