What did I miss?

use v5.12;
use warnings;
use Data::Dump qw/pp dd/;
use Test::More;

our $/="\n\n\n";
our @sets = <DATA>;

for (@sets) {
    my ($example) = /^(Example \d*):/m;
    my ($input)   = /^Input: (.*)$/m;
    my ($output)  = /^Output: (.*)$/m;
    $input =~ s(\$P)(;\$P);
    my ($S,$P);
    eval $input;

    #pp [$S,$P];

    my $re = glob2re($P);

    my $res = ($S =~ $re);
    is( 0+$res, $output, "$example $input");
}

done_testing;



sub glob2re {
    my ( $pat ) = @_ ;

    $_ = "\Q$pat";
    s/\Q\*/\.\*/g;
    s/\Q\?/\./g;

    return qr/^$_$/;
}



__DATA__
Example 1:

Input: $S = "abcde" $P = "a*e"
Output: 1


Example 2:

Input: $S = "abcde" $P = "a*d"
Output: 0


Example 3:

Input: $S = "abcde" $P = "?b*d"
Output: 0


Example 4:

Input: $S = "abcde" $P = "a*c?e"
Output: 1
[download]

C:/Perl_524/bin\perl.exe -w d:/tmp/pm/weekly_challenge.pl 
ok 1 - Example 1 $S = "abcde" ;$P = "a*e"
ok 2 - Example 2 $S = "abcde" ;$P = "a*d"
ok 3 - Example 3 $S = "abcde" ;$P = "?b*d"
ok 4 - Example 4 $S = "abcde" ;$P = "a*c?e"
1..4
[download]