Close enough ?

#!/usr/bin/perl

use strict; # https://perlmonks.org/?node_id=11132285
use warnings;

my @email = (
    'someone@example.co.uk',
    'andrew.test@some.company.co.uk',
    'jo@abc.com',
);

foreach my $em(@email) 
  {
  print "$em - ";
  $em =~ s/\w{2}\K(\w*)/ $1 =~ tr!!.!cr /ge;
  print "$em\n";
  }
[download]

Outputs:

someone@example.co.uk - so.....@ex......co.uk
andrew.test@some.company.co.uk - an.....te..@so...co......co.uk
jo@abc.com - jo@ab..co.
[download]

something like

  DB<98> say "$_:\t", $_ =~ s/(\w\w).*\@.*(\.\w*)/$1...\@...$2/r for q
+w/someone@example.co.uk andrew.test@some.company.co.uk jo@abc.com/

someone@example.co.uk:  so...@....uk
andrew.test@some.company.co.uk: an...@....uk
jo@abc.com:     jo...@....com
[download]

?

YMMV

edit

FWIW your code is (mostly) OK, but you should really always do it in an if-block to test for a successful match first

if( $em =~ /^(\w[\w|\.]).*@(\w\w).*\.(\w+)$/ ) {
    $em = $1 . '.' x (length($name) - 2) . "\@$2" . '.' x (length($com
+p) - length($3) - 2) . $3;
}
[download]

and you might get bitten by variable interpolation if you don't escape the "@" in a regex: \@

The obscured mails I know are normally shortened resp. normalized, may I suggest that you always use ... three dots?

Interesting...
That's pretty much what I put into production last evening. This is the live regexp:

$user->{'email'} =~ s/([\w|\.][\w|\.])[\w|\.]+\@(\w\w[\w|\.])[\w|\.]+\
+.([\w|\.]+)/\1...@\2.....\3/;
[download]

Although, looking at it again, it could be simplified. Email address don't start with a full stop!

you should really always do it in an if-block to test for a successful match first

I always do except for simple tests like the one I posted. I have been bitten by that before and spent a couple of long nights trying to work out what was wrong, only to find my regexp wasn't matching an edge case and my loop was using values from the previous iteration. It was years ago but frustrating enough that it is unforgettable!

you might get bitten by variable interpolation if you don't escape the "@" in a regex: \@

Yes - I've been bitten by that before as well.
You are quite right, even in a quick test I should have escaped that one.

Thanks for the helpful feedback

$em =~ /^(\w[\w|\.]).*@(\w\w).*\.(\w+)$/;

Note that in the [\w|\.] character class, the | (pipe) character matches a literal pipe character and is not an alternation. (I'm not sure if you intended a character match or not.) Also, escaping the . (period) character (\.) in the class is not needed, but does no harm.

I used [\w|\.] to match either a an alphanumeric character or a real full stop - did I get that wrong?

The beginning of \w[\w|\.] is to allow for cases where an email address consists of the person's initial followed by a full stop followed by their surname - e.g. j.bloggs@...

EDIT - I guess I wanted (\w|\.) instead of [\w|\.]

Here is how to use a character class to achieve that.

use strict;
use warnings;

use Test::More;

my @good = (
    'a',
    '9',
    '_',
);

my @bad = (
    '-',
    '$',
    '?',
);

my $re = qr/[\w.]/;

plan tests => @good + @bad;

like   $_, $re, "match for '$_'"    for @good;
unlike $_, $re, "no match for '$_'" for @bad;
[download]

---

🦛

See https://perldoc.perl.org/perlretut#Using-character-classes

Cheers Rolf
_{(addicted to the Perl Programming Language :)
Wikisyntax for the Monastery}

A bit shorter:

use strict;
use warnings;

my @email = (
    'someone@example.co.uk',
    'andrew.test@some.company.co.uk',
    'jo@abc.com',
);

foreach my $em(@email) {
    print "$em - ";

    $em =~ /^(\w[\w.])(.*)(\@\w\w)(.*)(\.\w+)$/;
    $em = $1 . '.' x length($2) . $3 . '.' x length($4) . $5;

    print "$em\n";
}
[download]

Or, you may like this:

use strict;
use warnings;

my @email = (
    'someone@example.co.uk',
    'andrew.test@some.company.co.uk',
    'jo@abc.com',
    );

for my $em ( @email ) {
    print "$em - ";

    ( my $at_pos = rindex $em, '@' ) > 0 or die "$em: invalid email ad
+dress.\n";
    ( my $dot_pos = rindex $em, '.' ) > $at_pos or die "$em: invalid e
+mail address.\n";
    tr//./c for substr( $em, 2, $at_pos - 2 ), substr( $em, $at_pos + 
+3, -( length( $em ) - $dot_pos ) );

    print "$em\n";                                        
    }
[download]

G'day Bod,

This looked a short, fun exercise. I threw this together before looking at any reponses.

$ perl -Mstrict -Mwarnings -E '
    my @email = (
        q{someone@example.co.uk},
        q{andrew.test@some.company.co.uk},
        q{jo@abc.com},
    );

    for my $email (@email) {
        my ($nm0, $nm1, $at, $ad0, $ad1, $tld)
            = $email =~ /^(..)([^@]*)(@)(..)(.*?)(\.[^.]+)$/;
        say $email;
        say $nm0, "."x length($nm1), $at, $ad0, "."x length($ad1), $tl
+d;
    }
'
someone@example.co.uk
so.....@ex.........uk
andrew.test@some.company.co.uk
an.........@so..............uk
jo@abc.com
jo@ab..com
[download]

There are some similarities to what others have posted.