Your intuition to use Algorithm::Combinatorics is correct, but your choice of functions within that module was incorrect. The correct function exists, and is documented in the POD: variations_with_repetition.

use Algorithm::Combinatorics qw(variations_with_repetition);

my @data = (1,2);
my $at_a_time = 3;

my $variations_iterator = variations_with_repetition(\@data, $at_a_tim
+e);

while (my $variant = $variations_iterator->next) {
    print "@$variant\n";
}
[download]

This produces:

1 1 1
1 1 2
1 2 1
1 2 2
2 1 1
2 1 2
2 2 1
2 2 2
[download]

You were so close!

In the future, please post the sample code. In this case I would have used it to verify that you were using the module correctly, aside from using the incorrect function.

Also, a lesson from high school math, and from the POD: There are n^k variations with repetition. So in your case the input set size is 2, and you're taking 3 at a time. 2**3=8. So we can validate that we got the correct number of variations by checking that we got 8, and that there are no repeats.

  DB<19> $dyn = 3

  DB<20> $gen = join " ", ("{1,2}") x $dyn

  DB<21> say for <"$gen">
1 1 1
1 1 2
1 2 1
1 2 2
2 1 1
2 1 2
2 2 1
2 2 2
[download]

HTH! :)

#!/usr/bin/perl

use strict; # https://perlmonks.org/?node_id=11132353
use warnings;

my @static = qw( 1 2 );
my $nonstatic = 3;

my @item = [];
@item = map { my $static = $_; map [ $static, @$_ ], @item } @static
  for 1 .. $nonstatic;

use Data::Dump 'dd'; dd \@item;
[download]

Outputs:

[
  [1, 1, 1],
  [1, 1, 2],
  [1, 2, 1],
  [1, 2, 2],
  [2, 1, 1],
  [2, 1, 2],
  [2, 2, 1],
  [2, 2, 2],
]
[download]

Just to make sure: You aren't trying to cheat on PWC 112, are you?

for ( 0 .. 2**$n-1 ) {
   my @combo = map { $_ + 1 } split //, sprintf("%0*b", $n, $_);
   say "@combo";
}
[download]

use Algorithm::Loops qw( NestedLoops );

my $iter = NestedLoops([
   map [ 1, 2 ], 1..$n
]);

while ( my @combo = $iter->() ) {
   say "@combo";
}
[download]

$amount = 3;
@pick = (1,2);
@end = ();

for($i=0;$i<$amount;$i++) {
 for($z=0;$z<2**($amount-1-$i);$z++) {
    for($j=0;$j<@pick;$j++) {
      for($k=0;$k<2**$i;$k++) {
           push(@{$end[$i]},$pick[$j]);       
      }
    }
  }
}
for($z=0;$z<2**($amount);$z++) {
  for($i=0;$i<$amount;$i++) {
    print $end[$i][$z]."\t";  
  }
  print "\n";
}
[download]