Not that I'm aware of. But you can always DIY:

$ perl -E 'grep { /^..(A|B)./ and push @f, $1 } @ARGV; say @f' xxBxx y
+yAyy
BA
$
[download]

  DB<31> push @N, /^..(A|B)./ for qw/xxBxx yyAyy zzNzz/

  DB<32> x @N
0  'B'
1  'A'
  DB<33>
[download]

Cheers Rolf
_{(addicted to the Perl Programming Language :)
Wikisyntax for the Monastery}

or even easier

  DB<34> @a = qw/xxBxx yyAyy zzNzz/

  DB<35> @N = map {/^..(A|B)./} @a

  DB<36> x @N
0  'B'
1  'A'
  DB<37>
[download]

Hint: m// returns an empty list if there's no match

Cheers Rolf
_{(addicted to the Perl Programming Language :)
Wikisyntax for the Monastery}

nice , TY u got an UPVOTE!

map { /^..(A|B)./ ? [ $_, $1 ] : () } @a
[download]

I got the sense that you didn't want just the captured parts. But if you only need the $1 from each match the above simplifies to

map { /^..(A|B)./ ? $1 : () } @a
[download]

but you could also go a step further and simply use

map /^..(A|B)./, @a
[download]

Update: Added what's after the break.

ikegami you are definitely a "blackbelt".

I expanded your code to show relevance to the OP's question.
Your map shows something that took me a long time to figure out,
how to return "nothing" from a map{}!

use strict;
use warnings;

my @x = ("aaBxyz", "..Bxys", "bbxyzzy", "xxAx");

my @result = map { /^..(A|B)./ ? [ $1, $_ ] : () } @x;

# @result is a "2-d array", references to "rows of array"
# I swapped $1 and $_ because I thought the print out looked better

# Of course every map{} can be expressed as a for loop...

foreach my $row_ref (@result)
{
   print "@$row_ref\n";
}

=PRINTS:
B aaBxyz
B ..Bxys
A xxAx
=cut
[download]

I think this code is well past what the OP wanted.

ADDED: If the OP wants a subset of something, think GREP. If the OP wants to transform an input into something else, think MAP.

I use a similar idiom in formulating a return responses or external calls, sometimes:

my ($stdout, $stderr, $ret) = capture {
    system('foo',
        ($somearg  ? ('--somearg'  => $somearg ) : ()),
        ($otherarg ? ('--otherarg' => $otherarg) : ()),
    );
};
[download]

...or...

return {
    status => $s,
    ($optional_field ? (optional_field => $optional_field) : ()),
};
[download]

Caveat emptor. The need to do either of these may constitute code smell, but sometimes purity has to give way to get it done-ery.




Dave

I got the sense that you didn't want just the captured parts. But if you only need the $1 from each match,

map { /^..(A|B)./ ? [ $_, $1 ] : () } @a
[download]

simplifies to

map { /^..(A|B)./ ? $1 : () } @a
[download]

but you could also go a step further and simply use

map /^..(A|B)./, @a
[download]

(I added this to the original post to show the options in one place.)

Seeking work! You can reach me at ikegami@adaelis.com

the parens in this statement might be moot

Do you mean that the () in (A|B) is kinda bad because it captures A or B as well as acting to place a limit around A|B? If so you can (?:A|B) instead which groups A|B, but doesn't capture the match.

If you mean something else, perhaps you would like to spell it out for us?

use strict;
use warnings;

my @x = ("aaBxyz", "..Bxys", "bbxyzzy", "xxAx");

# for each element in the array @x, 
# pass that element to the array @result if
# if the 3rd character is either A or B
# followed by at least one character.

my @result = grep {/^..(A|B)./}@x;

print "$_\n" for @result;

=prints
aaBxyz
..Bxys
xxAx
=cut
[download]

Ok, on second thought, here we go...

#ok, with a weird example of $1
@result = grep{ print "$1 $_\n" if /^..(A|B)./;
                /^..(A|B)./}@x;
                
=prints
B aaBxyz
B ..Bxys
A xxAx
=cut
@result is the same as above

# grep {} executes the code within the brackets and passes the input
# to @result depending upon the true/false value of the last statement
+.
[download]

I hope that this blizzard of replies to your post makes it clear that the parens do capture $1!

Perl regex is super duper cool and there is a way to not capture A or B into $1. But I think that syntax is way past what you are asking for.