Maybe you rather need a hash of arrays, HoA, using the names as the keys and arrays of numbers as values?

#!/usr/bin/perl
use warnings;
use strict;

my %hash;
my $name;
while (<DATA>) {
    chomp;
    if ($. % 2) {  # Even lines.
        $name = $_;
    } else {
        push @{ $hash{$name} }, $_;
    }
}

use Data::Dumper;
print Dumper \%hash;

__DATA__
James
40
Philip
12
James
35
James
26
James
15
Philip
27
[download]

$VAR1 = {
          'James' => [
                       '40',
                       '35',
                       '26',
                       '15'
                     ],
          'Philip' => [
                        '12',
                        '27'
                      ]
        };
[download]

Yes that is the exact output I was looking for. Thanks for your time!

A little closer to production code by opening a "file" and checking for unexpected data:

use strict;
use warnings;
use Data::Dumper;

my $testData = <<DATA;
>James
>40
>James
>35
>James
>26
>James
>15
DATA

open my $fin, '<', \$testData or die "Can't open file: $!\n";

my %people;
my $lastPerson;

while (defined (my $line = <$fin>)) {
    chomp $line;

    if ($line =~ /^>(\d+)$/) {
        die "Unexpected data order: '$line'\n" if !defined $lastPerson
+;
        push @{$people{$lastPerson}}, $1;
        next;
    }

    if ($line =~ /^>(\w+)$/) {
        $lastPerson = $1;
        next;
    }

    warn "Don't know how to process '$line'\n";
}

print Dumper(\%people);
[download]

Prints:

$VAR1 = {
          'James' => [
                       '40',
                       '35',
                       '26',
                       '15'
                     ]
        };
[download]

Looks like homework, but anyway. My stab is a little more defensive and allows multiple (0 .. n) values per key

use Data::Peek;
my %d;
while (<DATA>) {
    s/^\s*>?\s*(.*?)[\s\r\n]*\z/$1/;
    m/^(\d+)$/ ? push @{$d{$a}} => $1 : ($a = $_);
    }
DDumper \%d;

__END__
>James
>40 
>James
>35
>James
>26
>James
>15
James
10
>12
>Philip
10
4
>5
Philip
James
Philip
18
[download]

->

{   James            => [
        '40',
        '35',
        '26',
        '15',
        '10',
        '12'
        ],
    Philip           => [
        '10',
        '4',
        '5',
        '18'
        ]
    }
[download]

#!/usr/bin/perl -w

use strict;
use warnings;

my $TEXT = <<'END';
    >James
    >40
    >James
    >4
    >John
    >35
    >James
    >26
    >John
    >31
    >James
    >15
    >Pete
END

$TEXT =~ tr|a-zA-Z0-9||cd;        # Remove everything except letters a
+nd numbers

my @ARRAY = SplitNumbers($TEXT);  # Split numbers vs letters

if (@ARRAY & 1) { pop(@ARRAY); }  # Remove last element if it has no n
+umber following it.

my %HASH;                         # This is used as a global here

for (my $i = 0; $i < @ARRAY; $i+=2)
{
  if (exists($HASH{$ARRAY[$i]})) { $HASH{$ARRAY[$i]} .= ', '; }
  $HASH{$ARRAY[$i]} .= $ARRAY[$i+1];
}

print GetList('James');
print GetList('John');
print GetList('Pete');
print GetList('Bob');

exit;

##################################################
# Returns the named list in nicely formatted way.
#
# Usage: STRING = GetList(NAME)
#
sub GetList
{
  @_ or return '';
  my $NAME = shift;  # Get first argument, which is the 'NAME'

  return "\n   $NAME = [" . (exists($HASH{$NAME}) ? $HASH{$NAME} : '')
+ . "]\n";
}
##################################################
#
# Splits a string along numbers and returns an
# array of alternating numbers and text.
# Usage: ARRAY = SplitNumbers(STRING)
#
# Example: SplitNumbers('abc45tt-35203.19') -> ["abc", 45, "tt-", 3520
+3, ".", 19]
#
sub SplitNumbers
{
  defined $_[0] or return ();
  my ($PTR, $PREV, $LEN, $TYPE, @A) = (0, -1, length($_[0]));
  $LEN or return ();

# Possible values for $PREV: -1=Uninitialized 0=NUMBER 1=TEXT

  for (my $i = 0; $i < $LEN; $i++)
  {
    $TYPE = vec($_[0], $i, 8);
    $TYPE = $TYPE < 48 || $TYPE > 57;    # Is it a number?
    if ($PREV == !$TYPE)        # Same as before?
    {
      push(@A, substr($_[0], $PTR, $i-$PTR));
      $PTR = $i;
    }
    $PREV = $TYPE;
  }
  push(@A, substr($_[0], $PTR));    # Process last chunk
  return @A;
}
##################################################
[download]

This code outputs the following:

   James = [40, 4, 26, 15]

   John = [35, 31]

   Pete = []

   Bob = []
[download]