Perl has some - IMHO buggy - behavior if a lexical declaration happens in the head and not the body of a compound construct like if(HEAD){BODY} .

The compile-time scope ends right after the BODY is closed, hence the lexical is not anymore declared.

But the run-time destruction will only happen if the outer-scope - that's at least the file-scope° - is finished.

Any reason why?

In my book that's a design flow at least.

DEMO:

use strict;
use warnings;
use Data::Dump qw/pp dd/;

$\="\n";


our $PHASE=0;
{
    if ( my $x = bless {name=>"extra block"}, "TEST" ) {
        $PHASE=1;
        print $x;
    }
}                                       # DESTRUCTION

$PHASE=2;                               # line 16


if ( my $x = bless {name=>"head if"}, "TEST" ) {
    $PHASE=3;
    print $x;
}                                       # NO DESTRUCTION

# --- uncomment for compile-time error
# print $x;


print "";

$PHASE=4;

print "";                               # line 32



package TEST;
use Carp;

sub DESTROY {
    my ( $self ) = @_ ;
    carp "DESTROY <x: $self->{name}> <PHASE: $::PHASE>";
}
[download]

will produce this output

C:/Strawberry/perl/bin\perl.exe -w d:/tmp/pm/berny_open.pl 
DESTROY <x: extra block> <PHASE: 1> at d:/tmp/pm/berny_open.pl line 16
+.
DESTROY <x: head if> <PHASE: 4> at d:/tmp/pm/berny_open.pl line 32.
TEST=HASH(0x1ca7e8)
TEST=HASH(0x1ca8f0)
[download]

DISCLAIMER: This was just discussed at German.PM online meeting today and was motivated by this SO-Discussion.

updates

• °) it's even a bit weirder, the line number 25 of the carp indicates that it's happening at the end of the main-package, and not the file.
• expanded code with additional lines and comments
• changed bless syntax to avoid misunderstandings