The gen.sh is used to generate the directories:

glob.pl uses glob. It returns the entries sorted, so the last one is the future one, as dates sort alphabetically in the YYYYMMDD form (at least for the nearest future).

#!/usr/bin/perl
use warnings;
use strict;
use feature qw{ say };

use Time::Piece;

my $now = localtime->ymd("");

for my $dir (glob '???/') {
    say substr +(glob "$dir*/")[-1], 0, -1;
}
[download]

path.pl uses Path::Tiny.

#!/usr/bin/perl
use warnings;
use strict;
use feature qw{ say };

use Time::Piece;
use Path::Tiny qw{ path };

my $now = localtime->ymd("");

for my $dir (grep $_->is_dir, path('.')->children) {
    for my $date (grep $_->is_dir, $dir->children) {
        say $date if $date->basename > $now;
    }
}
[download]

readdir.pl uses opendir and readdir.

#!/usr/bin/perl
use warnings;
use strict;
use feature qw{ say };

use Time::Piece;

my $now = localtime->ymd("");

opendir my $dir, '.' or die $!;
while (my $pdir = readdir $dir) {
    next if $pdir =~ /^\.{1,2}$/ || ! -d $pdir;

    opendir my $ddir, $pdir or die $!;
    while (my $date = readdir $ddir) {
        next if $date =~ /^\.{1,2}$/ || ! -d $dir;

        say "$pdir/$date" if $date > $now;
    }
}
[download]

Run make compare to verify all three scripts give the same output.

The results on my machine were

make glob    > /dev/null

real    0m0.109s
user    0m0.054s
sys    0m0.053s
make readdir > /dev/null

real    0m0.074s
user    0m0.045s
sys    0m0.029s
make path    > /dev/null

real    0m0.440s
user    0m0.380s
sys    0m0.060s
[download]

You can see, readdir.pl has the most verbose code as it's the most low-level, but it's the fastest one. Glob is a bit slower, but still pretty good. Path::Tiny didn't really shine, but maybe its code can be improved.

Thank you thank you for the amazing examples & the benchmarks! Wow. You monks never cease to amaze me!

I suggest using Path::Tiny for working with the files: its visit method can recursively walk a directory tree and apply a subroutine to each filename found, accumulating a list of matching files. The solution to matching the filenames will depend on the naming format used.

Update: since you showed the format elsewhere ... try something like this:

use strict;
use warnings;
use feature 'say';
use Data::Dumper;
use Path::Tiny;
use Time::Piece;

my $root = "/Users/1nickt/perlmonks/11133966";
my $today = localtime->strftime('%Y%m%d');
my %list;

path($root)->visit(sub {
    my $path = shift;
    next unless -d $path;
    my $date = substr($path, -8);

    if ( $date =~ /^[0-9]{4}[0-2][0-9][0-3][0-9]$/ && $date gt $today 
+) {
        push(@{ $list{$_->parent} }, $path =~ s{.+/}{}r);
    }
}, {
    recurse => 1,
});

say Dumper \%list;
[download]

Hope this helps!

Thank you very much for your suggestion!! I will try this out!

Thank you for your response :) Yes, it's YYYYMMDD