Your extra parens don't do anything (as far as preserving structure) and you wind up with everything flattened out in one big array. You need a list of arrayrefs to initialize your array in order to keep your sub-lists distinct. See perllol and perldsc as well as perlreftut if you need the basics on references.

my @sites = ( [ "blah", "city", "url1" ], ... );
for my $row (@sites) {
  my( $zip, $name, $url ) = @{ $row };
  ...;
}
[download]

G'day guthrie,

As an alternative, consider an HoH (Hash of Hashes) instead of an AoA (Array of Arrays). If you need to add even more information at some later point, this may be a more flexible solution. Here's a quick-and-dirty example:

#!/usr/bin/env perl

use strict;
use warnings;

my %site_info = (
    50049 => {
        city => 'city1',
        url  => 'url1',
    },
    50219 => {
        city => 'city2',
        url  => 'url2',
    },
);

my $fmt = "ZIP: %s\n\tCity: %s\n\tURL: %s\n";

for my $zip (keys %site_info) {
    printf $fmt, $zip, @{$site_info{$zip}}{qw{city url}};
}
[download]

Output:

ZIP: 50219
        City: city2
        URL: url2
ZIP: 50049
        City: city1
        URL: url1
[download]

use strict;
use warnings;
my @sites=( ["50049", "city1", "url1"],
            ["52556", "city2", "url2"],
            ["50219", "city3", "url3"] );
foreach my $tuple (@sites) {
    my ( $zip, $name,  $url ) = @$tuple;
    ...;
}
[download]

Update: Added Links, corrected typo

Thank you very much (everyone), this is just what I wanted - I couldn't figure out the "@$tuple" syntax.

Another organizational structure: an array of hashes.

Win8 Strawberry 5.8.9.5 (32)  Thu 07/29/2021  7:25:26
C:\@Work\Perl\monks
>perl

use strict;
use warnings;

my @sites = (
    { 'zip' => '50049', 'city' => 'city1', 'url' => 'url1', },
    { 'zip' => '52556', 'city' => 'city2', 'url' => 'url2', },
    { 'zip' => '50219', 'city' => 'city3', 'url' => 'url3', },
    );

for my $hr_site (@sites) {

    my ($url, $zip, $city) = @{ $hr_site }{ qw(url zip city) };
    print "doing something in $city $zip with $url \n";

    print "also available directly: $hr_site->{'url'} \n\n";

    }

^Z
doing something in city1 50049 with url1
also available directly: url1

doing something in city2 52556 with url2
also available directly: url2

doing something in city3 50219 with url3
also available directly: url3
[download]

Perl (5) does not have a (built in) "tuple" data structure, as found in, e.g, Python. As already shown, use an array of array references instead.

"...I want more information..."

What about a tiny database like SQLite?

See also DBI and DBD::SQLite. Best regards, Karl