use strict;
use warnings;
use Test::More;

sub chunks {
    my $str   = "";
    while (my @cols = splice @_, 0, 3) {
        $str .= "@cols\n";
    }
    return $str;
}

#  ========= Tests

my @list = ("a", "bb", "c", "d", "e", "f", "g", "h");
my @old = @list;

my $text =
  "a bb c\n" .
  "d e f\n"  .
  "g h\n"
  ;


is( chunks(@list) => $text, "Rosetta's Example");

is( chunks() => "", "Empty string" );

is( chunks("") => "\n", "Empty List" );

is_deeply( \@list, \@old, "Non destructive! yeah ... :)");

done_testing;
[download]

NB: @_ is a array of aliases, not an alias itself. Destryoing it doesn't affect the argument given :)

Why splice when you can regex ?

#!/usr/bin/perl

use strict; # https://perlmonks.org/?node_id=861938
use warnings;

sub chunk_array
  {
  my $n = shift() - 1;
  "@_\n" =~ s/(?: \S*){$n}\K /\n/gr;
  }

my $v1 = chunk_array(3, "a", "bb", "c", "d", "e", "f", "g", "h");
$v1 eq "a bb c\nd e f\ng h\n" or die "error: '$v1'\n";
print $v1;

print "------------------------------\n";

my $v2 = chunk_array(3, "a", "bb", "c", "d", "e", "f");
$v2 eq "a bb c\nd e f\n" or die "error: '$v2'\n";
print $v2;
[download]

Outputs:

a bb c
d e f
g h
------------------------------
a bb c
d e f
[download]

Another one of the \K/r idiom that makes perl so great!

I'm surprised your username doesn't contain multiple / and 99

The gods would certainly grant your wish to transform it into an unreadable regex ... ;-P

Cheers Rolf
_{(addicted to the Perl Programming Language :)
Wikisyntax for the Monastery}