G'day Zsolt,

You have written your for loop like this:

for (INIT; COND; INCR) {
    ...
}
[download]

The following is very important. I'm not attempting to be patronising; you need to fully understand this. Pay close attention to the numbers.

INIT

This is an initialisation which only occurs once. In your case, it sets $i to 1.

COND

This is a condition which determines whether the loop is entered. When $i is 1, 2, 3, 4 or 5 the condition $i <= 5 is TRUE and the loop is entered. When $i is 6, the condition is FALSE, and the loop ends.

INCR

This increments $i at the end of the loop before another iteration is attempted. $i is set to 2 at the end of the 1st iteration. It continues to be incremented. $i is set to 6 at the end of the 5th iteration. The last value that $i has is 6!

In each iteration, you set up two callbacks with the -command option. In both cases, the value of the callback is a coderef (an anonymous subroutine: sub { ... }); You redefine those coderefs on each iteration. The code in those coderefs contains the variable $i. On the final redefinition, the last value that $i has is 6!

This is why, regardless of which CLR button you use, you always see "title: Choose color for 6 degree!"; and similarly, regardless of which CHK button you use, you always see "degreeClr6".

Using (non-reference) variables in a callback is almost always a bad idea in Tk applications: use references instead. Here's a somewhat contrived Tk application using two scalarrefs and an arrayref in a callback. It's possibly a little over the top; however, it's intended to make a point.

#!/usr/bin/env perl

use strict;
use warnings;

use Tk;

my $mw = MainWindow::->new();

my @colours = qw{magenta red blue green darkred};

my $swatch = $mw->Label(-bg => 'black')->pack(-fill => 'x');

for my $i (0 .. 4) {
    $mw->Button(
        -bg => $colours[$i],
        -command => sub {
            colour_swatch(\$swatch, \@colours, \$i);
        },
    )->pack(-fill => 'x');
}

sub colour_swatch {
    my ($swatch_ref, $colours_ref, $i_ref) = @_;

    my $bg = ${$colours_ref}[$$i_ref];

    $$swatch_ref->configure(-bg => $bg);

    return;
}

MainLoop;
[download]

The swatch at the top starts off black. As you click on any of the five coloured buttons below, it takes on the colour of that button.

You have no end of other problems with the code you posted: package variables springing into existence all over the place; symbolic references which you should really avoid (arrays and hashes are often a better choice — see @colours in my code above); lines so long that they're almost unreadable (one statement has 262 characters); and other code which I suspect you just threw at it in the hope that it would somehow fix something (for instance, what did think the utf pragma would achieve?).

I strongly recommend that you read perlintro to get a basic grounding in Perl coding. Following that, you may want to look at: "Symbolic references", "Anonymous Subroutines", and Tk::callbacks.

Your problem can be demonstrated by following simple code:

my @subs;
for(my $i=1;$i<=5;$i++){
        push @subs, sub {
                print "i=$i\n";
        };
}
$subs[3]->();
[download]

Inside the sub, $i is evaluated at the time the sub is called in the context/scope of the for-loop which has now terminated, so $i=5+1=6, which is the expected behaviour.

A workaround would be to create a sub via eval which will force it to consider $i's value at the time of the eval. But I am not sure if this is an elegant solution:

my @subs;
for(my $i=1;$i<=5;$i++){
        push @subs, eval <<EOE;
sub {
    print "i=$i\n";
};
EOE
}
$subs[3]->();
[download]

btw, once you sort this out, you should start using arrays instead of ${"xx$i"}!

Update: another solution would be to introduce another variable local to the loop scope and use that:

my @subs;
for(my $i=1;$i<=5;$i++){
        my $j = $i;
        push @subs, sub {
          print "i=$i, j=$j\n";
        };
}
$subs[3]->();
[download]

Question: what's the difference between $i and $j, don't they both have the same scope?

bw, bliako

The perl foreach (or its alias for) loop does not have this problem.

my @subs;
#for(my $i=1;$i<=5;$i++){
for my $i (1..5) {
        push @subs, sub {
                print "i=$i\n";
        };
}
$subs[3]->();
[download]

OUTPUT:

i=4
[download]

Bill

And this code confirms your finding:

my @subs;
for(my $i=1;$i<=2;$i++){ print \$i."\n" }
print "----\n";
for my $i (1..2) { print \$i."\n" }
[download]

OUTPUT:

SCALAR(0x55a429b66a28)
SCALAR(0x55a429b66a28)
----
SCALAR(0x56399466d4d8)
SCALAR(0x5639946924a0)
[download]

Which made me try this:

my @subs;
my $i;
for($i=1;$i<=5;$i++){
        push @subs, sub {
                print "i=$i\n";
        };
}
$i = 100;
$subs[3]->();
[download]

It prints i=100

bw, bliako

#for (my $i = 1; $i <= 5; $i++) {
for my $i (1..5) {
[download]

However, your script still does not execute correctly. (Error when pressing any of the CLR buttons.) Symbolic references are almost always a poor design choice. They are error prone and very hard to debug. (Largely because you have given up the benefit of use strict but also because of their strange syntax.) Your error message points to the offending line. After correcting two symbolic error bugs in that line, your program runs without error. I have no idea if it does what you intend.

   #$$clrCanvas -> itemconfigure(${$clrCanvasItem}, -fill => $color);
    $clrCanvas -> itemconfigure($clrCanvasItem, -fill => $color);
[download]