Is there a standard way to do it?

No but there are many ways to do it. Here is one:

#!/usr/bin/env perl 
use strict;
use warnings;

use List::Util 'reduce';
use Path::Tiny 'path';

my @files = qw/a b c/;
my $dir = '/tmp/';

print newest($dir, @files) . "\n";

sub newest {
    my $dir = shift;
    my $newest = reduce { $a->stat->mtime > $b->stat->mtime ? $a : $b 
+}
        map { path "$dir/$_" }
        @_;
    return "$newest";
}
[download]

I've passed the files as an array since that is much more useful (in a generic sense) than your hashref. Feel free to modify for your own purposes, of course. If your list of files is (or might be) very long then consider a transform to avoid excessive stat calls.

#!/usr/bin/perl

use strict; # https://perlmonks.org/?node_id=11140328
use warnings;
use List::AllUtils qw( max_by );

my $latest = max_by { (stat)[9] } glob 'tmp*'; # or your file list
print "latest = $latest\n";
[download]

Variation on the above theme for an instance if you actually wanted all of the files ordered newest to oldest and not just the newest:

my @files_by_age = 
  map  { $_->[1] }
  sort { $b->[0]<=>$a->[0] }
  map  { [ $_->stat->mtime, $_ ] } 
  grep { $_->is_file } 
  path( q{/tmp} )->children();
[download]

perl -E "say+(sort{(stat$a)[9]<=>(stat$b)[9]}grep{-f}glob'*')[-1]"
[download]

L*

PS sorry.. the latest is indexed -1 not 0 which is the oldest