Re^7: How to identify the package of a subroutine given only a reference to it

Benchmarking is always tricky: providing subrefs to benchmark makes it easier to get the code right, but if the target code is very fast the sub call overhead can swamp the results. Providing strings instead gets rid of that overhead, but is far harder to get right because the code will be evalled in a different context.

Using a string version of the benchmark, I confirm your results on my system perl (5.28) but the difference almost entirely disappears with 5.34 (which is also quite a bit faster overall):

% perl benchmark
               Rate methodic   blessy   direct
methodic 16017006/s       --     -31%     -40%
blessy   23189661/s      45%       --     -13%
direct   26673243/s      67%      15%       --

% /opt/v5.34.0/bin/perl benchmark
               Rate methodic   blessy   direct
methodic 21275455/s       --     -39%     -39%
blessy   34927866/s      64%       --      -0%
direct   35023414/s      65%       0%       --

% cat benchmark
use strict;
use warnings;
use Benchmark;

our($mcount, $bcount, $dcount) = (0) x 3;
package Methodic {
    sub new { return bless {} }
    sub method { ++$::mcount }
};
package Blessy {
    sub new { return bless sub { ++$::bcount } }
};
sub direct { ++$::dcount }

our $methodic = Methodic->new;
our $blessy = Blessy->new;
our $direct = \&direct;

Benchmark::cmpthese(-1, {
    methodic => q{$::methodic->method()},
    blessy => q{$::blessy->()},
    direct => q{$::direct->()},
});
%
[download]

Note also that if you look at the counts after the benchmark has run, you'll see larger number than those that were reported. IIRC this is because Benchmark tries to calculate the overhead of calling and adjust results for it, and should not be taken as a sign that it can't count. :)

Comment on Re^7: How to identify the package of a subroutine given only a reference to it Download Code

Replies are listed 'Best First'.
Re^8: How to identify the package of a subroutine given only a reference to it by drclaw (Acolyte) on Feb 19, 2022 at 04:37 UTC
Thanks for the reply and benchmark insights. What OS are you running? Running your benchmark on my laptop with macOS 12.1 with perl 5.34 I get similar percentage differences to my original benchmark code: `macOS 12.1, your benchmark code: Rate methodic blessy direct methodic 16445180/s -- -27% -35% blessy 22503930/s 37% -- -11% direct 25252404/s 54% 12% -- macOS 12.1, rerun of my original benchmark code: Rate method blessed sub method 17857143/s -- -35% -44% blessed 27397260/s 53% -- -14% sub 31746032/s 78% 16% --` [download]	[reply] [d/l]
Re^9: How to identify the package of a subroutine given only a reference to it by hv (Prior) on Feb 19, 2022 at 13:37 UTC
My machine is running Ubuntu 18.04, but I would expect the OS to make little difference to such figures: the build options for perl would be far more important. For my 5.34 the relevant ones are `-Dcc=gcc-9 -Doptimize="-g -O6" -Duse64bitall`. In particular it would not surprise me if a `-DDEBUGGING` build slowed down operations on blessed coderefs relative to unblessed ones.	[reply] [d/l] [select]
Re^10: How to identify the package of a subroutine given only a reference to it by drclaw (Acolyte) on Feb 20, 2022 at 00:15 UTC
Interesting. The macports perl 5.34 install I'm using has optimize='-O3'. On my Debian virtual machine with perlbrew perl 5.34 I have optimise='-O2'. I'll dig a little deeper/learn about more when I get a chance.	[reply]