Here’s variation on trippledubs’ solution using the 3-dot form of the flip-flop operator:

#! perl
use strict;
use warnings;

my $re = qr{^//\*+$};

while (<DATA>)
{
    if (my $seq = /$re/ ... /$re/)
    {
        if ($seq > 1 && $seq !~ /E0$/)
        {
            print if m{^//\s*\S+};
        }
    }
}

__DATA__
// useless comment

Some Code

//**********************************************************
//
//I need that text
//   And that also
//
//**********************************************************

Some Code

// useless comment

//**********************************************************
// More text
//**********************************************************

More code
[download]

Update: Changed print unless m{^//$}; to print if m{^//\s*\S+}; to filter-out non-comment lines.

Output:

 1:25 >perl 1128_SoPW.pl
//I need that text
//   And that also
// More text

 1:25 >
[download]

Hope that helps,

Athanasius,

Love your posts. Looking at Athanasius's home node links like 7 Stages of Regex Users now, great tips and thanks for linking them.

++ Athanasius to address me to the 3 dot form: never realized it exists!!
L*

There are no rules, there are no thumbs..
Reinvent the wheel, then learn The Wheel; may be one day you reinvent one of THE WHEELS.

#!/usr/bin/env perl
use strict;
use warnings;

my $flag;
while (<DATA>) {
   if (/\/\*/) {
      $flag=!$flag; #turns on and off
      next;
   }
   if ( ($flag) && /\/{2,2}(.*)/) {
      print "$1\n";
   }
}

__DATA__
// useless comment

Some Code

//**********************************************************
//
//I need that text
//   And that also
//
//**********************************************************

Some Code

// useless comment
[download]

#!/usr/local/bin/perl
use strict;
use warnings;

$_ = <<'EOT';
// useless comment

Some Code

//**********************************************************
//
//I need that text
//   And that also
//
//**********************************************************

Some Code

//**********************************************************
//
//I need that text
//   And that also
//
//**********************************************************

Some Code

// useless comment

Some Code

//**********************************************************
//
//I need that text
//   And that also
//   And some more
//
//**********************************************************

Some Code

// useless comment
EOT
my $i = 0;
while (m|^//\*+\s*^.+?(\w[^*]+\w).+?^//\*+\s*$|smg) {
    printf "%d:\n%s\n\n", ++$i, $1;
}
__END__
1:
I need that text
//   And that also

2:
I need that text
//   And that also

3:
I need that text
//   And that also
//   And some more
[download]

^//\*+\s+^.+?^//\s*(\w.+?)\s*^//\s*(\w.+?$).+?^//\*+\s+$
[download]