Re: How to use sprintf %n formatting pattern

Here's an approach that achieves what you ask for. As mentioned earlier, it is pretty insane to do this - doing it in two separate steps makes far more sense - but it is possible.

% cat t0
use strict;
use warnings;

my $max_width = shift @ARGV;
my $prefix = "foo";
my $postfix = "0123456789";
my $stored_width;
tie my $limit, 'LazyScalar', sub { $max_width - $stored_width };

printf "%s%n%.*s\n", $prefix, $stored_width, $limit, $postfix;

# A simple tied class for deferred evaluation of a scalar's value
package LazyScalar {
    sub TIESCALAR {
        my($class, $cb) = @_;
        return bless \$cb, $class;
    }
    sub FETCH {
        my($self) = @_;
        return $$self->();
    }
};

% perl t0 6
foo012
% perl t0 7
foo0123
% perl t0 8
foo01234
%
[download]

Comment on Re: How to use sprintf %n formatting pattern Download Code

Replies are listed 'Best First'.
Re^2: How to use sprintf %n formatting pattern by GrandFather (Saint) on Jun 09, 2022 at 12:50 UTC
When I run your code I get: `Use of uninitialized value $max_width in subtraction (-) at delme.pl l +ine 26. foo0123456789` [download] which is about what I'd have expected due to the arguments to printf being evaluated before printf is called. What am I missing here? Optimising for fewest key strokes only makes sense transmitting to Pluto or beyond	[reply] [d/l]
Re^3: How to use sprintf %n formatting pattern by hv (Prior) on Jun 09, 2022 at 13:54 UTC
which is about what I'd have expected due to the arguments to printf being evaluated before printf is called I'm still not sure what you mean by that. If you call `foo($a + $b)`, perl will calculate `$a + $b` putting the result in a temporary scalar variable, and put that temporary scalar variable on the stack to call `foo()`. If you call `foo($a)`, perl will put the scalar variable `$a` on the stack, and call `foo()`. In the case of `printf("%s%n%.s\n", $prefix, $stored_width, $limit, $postfix)`, we get (effectively) references to each of those variables on the stack (at the C level, they are just `SV` pointers) - you know they have to be references, since `printf` needs to be able to write to `$stored_width`. At the point the `printf` implementation needs the next argument as a number, it'll ask the relevant scalar what its numeric value is; if it needs a string, it'll ask for that instead, etc. Is that making it any clearer?	[reply] [d/l] [select]
Re^4: How to use sprintf %n formatting pattern by GrandFather (Saint) on Jun 09, 2022 at 21:10 UTC
Yes, that too came clear in the shower this morning. I think my issue may be related to usually copying arguments into local variables as a first thing so I tend to forget about the aliasing that goes on. You might say I'm 'closing' in on understanding now. :-) Optimising for fewest key strokes only makes sense transmitting to Pluto or beyond	[reply]
Re^3: How to use sprintf %n formatting pattern by hv (Prior) on Jun 09, 2022 at 13:41 UTC
If `$max_width` is undefined, you probably ran it without providing a command-line argument. Try setting `$max_width` to something.	[reply] [d/l] [select]
Re^4: How to use sprintf %n formatting pattern by GrandFather (Saint) on Jun 09, 2022 at 21:05 UTC
Yup, figured that out in the shower this morning. I understand egg on the face is good for the complexion. Not sure why a shower is at least as effective as two coffees. Unfortunately the effect seems only to last for the duration of the shower. Optimising for fewest key strokes only makes sense transmitting to Pluto or beyond	[reply]
Re^3: How to use sprintf %n formatting pattern by hippo (Archbishop) on Jun 09, 2022 at 13:24 UTC
It works fine for me: `This is perl 5, version 34, subversion 0 (v5.34.0) built for x86_64-linux-thread-multi`. 🦛	[reply]