Re: Challenge: Parse XML Feed for Youtube channel -- Mojo::DOM

Here my solution with Mojo::DOM

(my first steps, I'm sure there is room for improvement)

FWIW: I shortened the input in DATA to two entries to keep it short.

use v5.12;
use warnings;
use Mojo::DOM;

my $data = join "", <DATA>;

my $dom = Mojo::DOM->new($data);

my $title = $dom->at('title')->text;
my $name  = $dom->at('name')->text;

say <<__HTML__;

<h3>$title</h3>
<b>$name</b>

<ul>
@{[
    entries()
]}
</ul>
__HTML__


sub entries {
    my @res;
    for my $entry ( $dom->find('entry')->each ) {

        my $title = $entry->at("title")->text;
        my $href  = $entry->at("link")->attr('href');
        my $desc  = $entry->at('media\:group > media\:description')->t
+ext;

        push @res, <<__HTML__;

    <li>[$href|$title]<p>
       $desc
    </li>
__HTML__
    }
    return @res;
}
[download]

OUTPUT

<h3>TPC 2022 in Houston</h3> <b>Conference in the Cloud! A Perl and Raku Conf</b> <ul> <li>[https://www.youtube.com/watch?v=waHAGThlRH8|Raku -Ofun for Ev +eryone - Daniel Sockwell]<p> Rakoons like to say that Raku is -Ofun (optimized for fun). Thi +s talk ... YADDA YADDA ... </li> <li>[https://www.youtube.com/watch?v=3BYlObnzuKQ|Introducing Perl +Data Types - Will Braswell]<p> Data types are hints to a computer language, telling the langua +ge’s ... YADDA YADDA ... </li> </ul>
[download]

Cheers Rolf
_{(addicted to the Perl Programming Language :)

Wikisyntax for the Monastery}

update

shortened description to ... YADDA YADDA ... for line wrap

Comment on Re: Challenge: Parse XML Feed for Youtube channel -- Mojo::DOM Select or Download Code

Replies are listed 'Best First'.
Re^2: Challenge: Parse XML Feed for Youtube channel -- Mojo::DOM by LanX (Saint) on Jun 29, 2022 at 11:05 UTC
Here a new approach with Mojo::DOM and taking benefit from it's overloading to shorten `->text` and `->attr` methods away. Also using an own rolled "template system" for readability The explicit `map` in the callback might also be easier done with an Mojo::DOM method ... maybe? use v5.12; use warnings; use Mojo::DOM; my $data = join "", <DATA>; my $dom = Mojo::DOM->new($data); say &t::page( TITLE => $dom->at('title'), NAME => $dom->at('name'), ENTRIES => \&entries, ); sub entries { map { t::entry ( TITLE => $_->at("title"), HREF => $_->at("link")->{href}, DESC => $_->at('media\:group > media\:description') ); } $dom->find('entry')->each ; } package t; # poor man's templates sub page { my %p = @_; << "____" } <h3>$p{ TITLE }</h3> <b>$p{ NAME }</b> <ul> @{[ $p{ ENTRIES }->() ]} </ul> ____ sub entry { my %p = @_; << "____" } <li>[$p{ HREF }\|$p{ TITLE }]<p> $p{ DESC } </li> ____ package main; [download] <Reveal this spoiler or all in this thread> Cheers Rolf _{(addicted to the Perl Programming Language :) Wikisyntax for the Monastery}	[reply] [d/l] [select]

Replies are listed 'Best First'.

Re^2: Challenge: Parse XML Feed for Youtube channel -- Mojo::DOM
by LanX (Saint) on Jun 29, 2022 at 11:05 UTC

Mojo::DOM

->text

->attr

Also using an own rolled "template system" for readability

The explicit map in the callback might also be easier done with an Mojo::DOM method ... maybe?

use v5.12;
use warnings;
use Mojo::DOM;

my $data = join "", <DATA>;

my $dom = Mojo::DOM->new($data);

say &t::page(
   TITLE   => $dom->at('title'),
   NAME    => $dom->at('name'),
   ENTRIES => \&entries,
  );


sub entries {
    map {
        t::entry
            (
             TITLE => $_->at("title"),
             HREF  => $_->at("link")->{href},
             DESC  => $_->at('media\:group > media\:description')
            );
    } $dom->find('entry')->each ;
}


package t;                              # poor man's templates

sub page { my %p = @_; << "____" }

  <h3>$p{ TITLE }</h3>
  <b>$p{ NAME }</b>

  <ul>
  @{[   $p{ ENTRIES }->()  ]}
  </ul>
____


sub entry { my %p = @_; << "____" }

    <li>[$p{ HREF }|$p{ TITLE }]<p>
       $p{ DESC }
    </li>
____



package main;
[download]

Cheers Rolf
_{(addicted to the Perl Programming Language :)

Wikisyntax for the Monastery}

[reply]
[d/l]
[select]