in reply to skip junk lines in csv before header

Alternate solution. Let perl do the work for you. 

#!/usr/bin/perl

use strict; # https://perlmonks.org/?node_id=11145686
use warnings;

open my $fh, '<', \<<END or die; # FIXME for testing
first junk line then a blank line

   another junk line
fieldname1,fieldname2
value1,value2
more,body
and,still
more,body
END

do { local $/ = "fieldname"; <$fh> };  # read through "fieldname"
my $header_line = "fieldname" . <$fh>; # complete the line

print "header: $header_line";
while( <$fh> ) # FIXME for testing
  {
  print "  body: $_";
  }

[download]

Outputs: 

header: fieldname1,fieldname2
  body: value1,value2
  body: more,body
  body: and,still
  body: more,body

[download]

Replies are listed 'Best First'.
Re^2: skip junk lines in csv before header
by GotToBTru (Prior) on Jul 28, 2022 at 12:19 UTC
    Can you explain how line 17 works? I see <$fh> only reads up to the end of line each time. What causes the do statement to complete?

    But God demonstrates His own love toward us, in that while we were yet sinners, Christ died for us. Romans 5:8 (NASB)
[reply]
[d/l]
      do { local $/ = "fieldname"; <$fh> };  # read through "fieldname"

      [download]

      The local $/ = "fieldname"; statement sets the $/ input record separator special variable (see perlvar) to the literal 'fieldname' string. This sets "paragraph" read mode: (no: see Update below) | This causes <$fh> to read the input stream from the beginning of the file (in this particular case) until the end of the first point at which the 'fieldname' string is encountered. Since the field names are apparently unambiguously known, this reads (almost) all the way through the first field name. The $/ variable is assigned local-ly in a do-block, so it returns to its previous value (the "\n" default in this case) at the end of the block. 

      my $header_line = "fieldname" . <$fh>; # complete the line

      [download]

      Since we (apparently) know the header line begins with 'fieldname', assign $header_line this initial value and complete reading the line with another <$fh>. This reads through the end of the line because $/ has restored to its original newline value.

      Update:

      This sets "paragraph" read mode: ...
      No, this is not "paragraph" (sometimes called "paragrep") read mode, it is normal read mode. See $/ in perlvar for a discussion of paragraph mode.

      In normal read mode, a file is read until just after the sequence of one or more characters in the $/ special variable is encountered (and including that sequence), or until the end of file if the $/ sequence is never encountered. Usually, $/ is a single "\n" (newline) character, but it can be any non-empty string. Whatever non-zero-length sequence of characters it may be, this is normal read mode.

      Give a man a fish:  <%-{-{-{-<

[reply]
[d/l]
[select]
      The do is actually redundant, he can use a basic block for localizing the $INPUT_RECORD_SEPARATOR aka $/

      use v5.12;
use warnings;
use Data::Dump qw/pp dd/;

say pp $/;                              # show default

say my $x =
  "HEADER\n" x 3 .
  "fieldname: BLA BLA\n" .
  join $/, 1..5;

open my $fh, '<', \$x;

# ignore anything prior to "fieldname"
{ local $/ = "fieldname:"; <$fh> };

say pp $/;                              # back to default

say "-" x 10;

say "fieldname:" . <$fh>;               # till end of line

      [download]

      "\n"
HEADER
HEADER
HEADER
fieldname: BLA BLA
1
2
3
4
5
"\n"
----------
fieldname: BLA BLA

      [download]

      Cheers Rolf
      (addicted to the Perl Programming Language :)
      Wikisyntax for the Monastery

[reply]
[d/l]
[select]

        It occurs to me that there might be a use for a do-block. If no 'fieldname' string is present in the file, <$fh> will read to the end of the file. This will be a valid read. If the data of the read is returned as from a do-block, it can be tested to determine if a header was actually present. (The data could be returned from a "naked" block, but using a do-block is neater IMHO.) 

        Win8 Strawberry 5.8.9.5 (32)  Thu 07/28/2022 11:22:44
C:\@Work\Perl\monks
>perl

use strict;
use warnings;

use Data::Dump qw(dd);

use constant FIELDNAME => 'fieldname';

open my $fh, '<', \<<END or die;
no valid header present
value1,value2
END

my $got_header = do { local $/ = FIELDNAME;  <$fh>; };
dd $got_header;  # for debug
$got_header =~ m{ \Q${ \FIELDNAME }\E \z }xms or die "no header";

my $header_line = FIELDNAME . <$fh>; # complete the line
# and so on...

^Z
"no valid header present\nvalue1,value2\n"
no header at - line 16, <$fh> line 1.

        [download]

        Give a man a fish:  <%-{-{-{-<

[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom