@doubled = map { ($_) x 2 } @array

edit

FWIW, you could of course also do

@doubled = (@array) x 2

but the order would be different.

a b c d a b c d

Thanks! :)

Another alternative is to list each element twice explicitly in the map:

@doubled = map { $_, $_ } @array
[download]

Also, you can construct the new array in a loop instead of using map:

my @doubled;
for my $elt (@array) {
    push @doubled, $elt, $elt;
}
[download]

Thank you! :)

List::Util is a core module (ships with Perl). It provides the mesh() function, which can be used as follows:

my @doubled = mesh \@array, \@array;
[download]

It turns out to be really quick.

#!/usr/bin/env perl

use v5.36;

use strict;
use warnings;
use Benchmark qw(cmpthese);
use List::Util qw(mesh);

my @array = ('a' .. 'z');

cmpthese(
    -5,
    {
        mapped => \&mapped,
        meshed => \&meshed,
    },
);

sub mapped {
    return [map {$_,$_} @array];
}

sub meshed {
    return [mesh \@array, \@array];
}
[download]

The output:

           Rate mapped meshed
mapped 111262/s     --   -51%
meshed 226692/s   104%     --
[download]

When I bump it up to 676 elements ('aa' .. 'zz'), the comparison is similar:

         Rate mapped meshed
mapped 4157/s     --   -50%
meshed 8262/s    99%     --
[download]

With 11756 elements ('aaa' .. 'zzz') the ratio holds.

Note that the first method of LanX and Corion also works if assigning the doubled/tripled/etc. array directly back to the source array:

Win8 Strawberry 5.8.9.5 (32)  Thu 07/28/2022  5:30:16
C:\@Work\Perl\monks
>perl

use strict;
use warnings;

use Data::Dump qw(dd);

my @ra = qw(a b c d);

my $n = 3;
@ra = map { ($_) x $n } @ra;
dd \@ra;

^Z
["a", "a", "a", "b", "b", "b", "c", "c", "c", "d", "d", "d"]
[download]

Awesome, thank you! :)

You have some good answers from other Monks so now you can do this if you want.

My question is: why do you want to do this? It will double/n-fold the memory footprint of your array for very little benefit. It sounds a little bit like an XY Problem. Would you care to elaborate?

ahah don't worry, this is to handle a very particular case in my script (not the general case, and hard to explain without context), so here it provides a fair solution to my problem, with a good benefit. But I understand your comment, since usually we want to do the opposite (get rid of the duplicates) ;)

sounds like homework.

..if homework a oneliner is needed :D

perl -MData::Dump -M"5;push @ARGV,reverse @ARGV" -e "push @m,shift,pop while @ARGV;dd @m" a b c

("a", "a", "b", "b", "c", "c")

L*

PS hello soblanc and welcome to the Monastery and to the wonderful world of Perl!

There are no rules, there are no thumbs..
Reinvent the wheel, then learn The Wheel; may be one day you reinvent one of THE WHEELS.