You can use @- and @+ to find the offsets within the string of respectively the start and the end of each capture. If you collect those (annotated as start or end) and reverse sort them, you can then insert your formatting codes backwards from the end of the string without having to worry about offsets moving under your feet.

How do you want it annotated if there are nested captures, such as with "foobar" =~ /f(o(ob)a)r/? The obvious choice would be to annotate them in different colours, but that then requires extra care - nested tags would need "f[GREEN]o[RED]ob[/RED]a[/GREEN]r", while non-nested would need "f[GREEN]o[RED]ob[GREEN]a[DEFAULT]r".

#!/usr/bin/perl

use strict; # https://perlmonks.org/?node_id=11146126
use warnings;

# Given path: /a/b/c/d
# Given regex: ^/a/b/([^/]*)/([^\/]*)
# Output: /a/b/\033[1;31mc\033[0m/\033[1;31md\033[0m

my ($boldred, $reset) = ( "\e[1;31m", "\e[0m" );

my $string = '/a/b/c/d/';
my $regex = qr{^/a/b/([^/]*)/([^\/]*)/};

$string =~ $regex or die "no match of $string by $regex";
my $coloredstring = $string;

my $count = @- - 1;
for ( reverse 1 .. $count )
  {
  substr $coloredstring, $+[$_], 0, $reset;
  substr $coloredstring, $-[$_], 0, $boldred;
  }

print "$coloredstring\n";
use Data::Dump 'dd'; dd 'coloredstring', $coloredstring;
[download]

Outputs:

/a/b/c/d/
("coloredstring", "/a/b/\e[1;31mc\e[0m/\e[1;31md\e[0m/")
[download]

So, what would be the best way

Everyone will have different criteria for "best". Here, for example is the most generic approach to wrapping your capture groups inside an arbitrary string. This is best for teaching you how to achieve such a result in a perfectly general way without necessarily being the best way to achieve the stated objective. :-)

use strict;
use warnings;

use Test::More tests => 1;

my $str  = '/a/b/c/d';
my $re   = qr#^/a/b/([^/]*)/([^\/]*)#;
my $want = "/a/b/\033[1;31mc\033[0m/\033[1;31md\033[0m";

my @caps = $str =~ $re;
my $out  = '/a/b/' . join '/', map {"\033[1;31m$_\033[0m"} @caps;

is $out, $want, "Matched '$want'";
[download]

G'day ovedpo15,

I see others have shown you how to access the captured text.

"I came a cross with the Term::ANSIColor module which can help me color the string without writing the color codes myself."

I wasn't sure if you were asking for help using Term::ANSIColor. In case you were, here's a demo. I do recall that I found the documentation difficult to follow when I first used it. By the way, it's a core module: no need to install it.

#!/usr/bin/env perl

use strict;
use warnings;

use Term::ANSIColor;

my $path = '/a/b/c/d';
my $re = qr{^/a/b/([^/]*)/([^\/]*)};
my $demo_fmt = '%-28s : ';

printf $demo_fmt, 'Input  - plain text from OP';
print "$path\n";

if (my @matches = $path =~ /$re/) {
    my $debug_path = $path;

    for (reverse 1 .. $#-) {
        substr $debug_path, $-[$_], $+[$_] - $-[$_],
                colored($matches[$_ - 1], 'red');
    }

    printf $demo_fmt, 'Output - "c" & "d" are red';
    print "$debug_path\n";

    printf $demo_fmt, 'Output - internals of string';
    use Data::Dump;
    dd $debug_path;
}
[download]

Prints:

Input  - plain text from OP  : /a/b/c/d
Output - "c" & "d" are red   : /a/b/c/d
Output - internals of string : "/a/b/\e[31mc\e[0m/\e[31md\e[0m"
[download]